Application Center - Maplesoft
  Submit your work
Application Center Applications Section 2.1 Functions of a Complex Variable Preview

App Preview:

Section 2.1 Functions of a Complex Variable

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

 

C02-1.mws

COMPLEX ANALYSIS: Maple Worksheets,  2001
(c) John H. Mathews          Russell W. Howell
mathews@fullerton.edu     howell@westmont.edu

Complimentary software to accompany the textbook:

COMPLEX ANALYSIS: for Mathematics & Engineering, 4th Ed, 2001, ISBN: 0-7637-1425-9
Jones and Bartlett Publishers, Inc.,      40  Tall  Pine  Drive,      Sudbury,  MA  01776
Tele.  (800) 832-0034;      FAX:  (508)  443-8000,      E-mail:  mkt@jbpub.com,      http://www.jbpub.com/


CHAPTER 2   COMPLEX FUNCTIONS

Section 2.1  Functions of a Complex Variable

    A complex valued function f  of the complex variable z is a rule that assigns to each complex number z in a set D one and only one complex number w . We write w = f(z) and call w the image of z under f . The set D is called the domain of f , and the set of all images {w = f(z), z*epsilon*D} is called the range of f . As we saw in section 1.6, the term domain is also used to indicate a connected open set. When speaking about the domain of a function, however, mathematicians mean only the set of points on which the function is defined. This is a distinction worth noting.
        
    Just as z can be expressed by its real and imaginary parts, z = x+i*y , we write f(z) = u+i*v , where u and v are the real and imaginary parts of w , respectively. This gives us the representation

     w  = f(z) = f(x, y) = f(x, y) = u+i*v .  

Since u and v depend on x and y , they can be considered to be real valued functions of the real variables x and y ; that is

     u = u(x, y)  and  v = v(x, y) .     

Combining these ideas it is customary to write a complex function  f  in the  form

     f(z) = f(x, y) = u(x, y)+i*v(x, y) .  

Definition.  A function  f(z)  of the complex variable  z  can be written:

    f(x+i*y) = u(x, y)+i*v(x, y) .

Definition.  The polar coordinate form of a complex function is:

     f(r*exp(i*theta))  =  u(r, theta)+i*v(r, theta) .

There are two approaches to defining a complex function in Maple.

Method 1. Make  f(x, y)  a function of two real variables  x, y .

Method 2. Make  f(z)  a function of the complex variable  z .


Example 2.1, Page 49.  Write  f(z) = z^4  in the  f = u+i*v  form.  

Method 1. Make  f(x, y)  a function of two real variables  x, y .

> f:='f': x:='x': y:='y': z:='z':
f := proc(x,y)
 local z,w;
 z := x + I*y;
 w := expand(z^4);
end:
`f(z) ` = z^4;
`f(x,y) ` = f(x,y); ` `;
`At  z = 1 + 2i: `;
`f(1,2) ` = f(1,2);

`f(z) ` = z^4

`f(x,y) ` = x^4+4*I*x^3*y-6*x^2*y^2-4*I*x*y^3+y^4

` `

`At z = 1 + 2i: `

`f(1,2) ` = -7-24*I

Method 2. Make  f(z)  a function of  z .

> F:='F': x:='x': y:='y': z:='z':
F := proc(z)
 local w;
 w := expand(z^4);
end:
`F(z) ` = F(z);
`F(x + I y) ` = F(x + I*y); ` `;
`At  z = 1 + 2i: `;
`F(1 + I 2) ` = F(1 + I*2);

`F(z) ` = z^4

`F(x + I y) ` = x^4+4*I*x^3*y-6*x^2*y^2-4*I*x*y^3+y^4

` `

`At z = 1 + 2i: `

`F(1 + I 2) ` = -7-24*I

Example 2.2, Page 50.  Write  f(z) = conjugate(z)*Re(z)+z^2+Im(z)  in the  f = u+i*v  form.

Method 1. Make  f(x, y)  a function of two real variables  `(x,y)` .

> f:='f': x:='x': y:='y':
f := proc(x,y)
 local w;
 w := (x - I*y)*x + (x + I*y)^2 + y;
end:
`f(x,y) ` = f(x,y);
`f(x,y) ` = evalc(f(x,y)); ` `;
`At  z = 1 + 2i: `;
`f(1,2) ` = f(1,2);

`f(x,y) ` = (x-I*y)*x+(x+I*y)^2+y

`f(x,y) ` = 2*x^2-y^2+y+I*x*y

` `

`At z = 1 + 2i: `

`f(1,2) ` = 2*I

Method 2. Make  f(z)  a function of  z .

> F:='F': x:='x': y:='y': z:='z':
F := proc(z)
 local w;
 w := conjugate(z)*Re(z) + z^2 + Im(z);
end:
`F(z) ` = F(z);
`F(x + I y) ` = (x-I*y)*x + (x+I*Y)^2 + y; ` `;
`At  z = 1 + 2i: `;
`F(1 + I 2) ` = F(1 + I*2);

`F(z) ` = conjugate(z)*Re(z)+z^2+Im(z)

`F(x + I y) ` = (x-I*y)*x+(x+I*Y)^2+y

` `

`At z = 1 + 2i: `

`F(1 + I 2) ` = 2*I

Example 2.3, Page 50.   Express  f(z) = 4*x^2+i*4*y^2  by a formula involving  z  and  conjugate(z) .  

Method 1. Make  f(x, y)  a function of two real variables  `(x,y)` .

> f:='f': x:='x': y:='y':
f := proc(x,y)
 local w;
w := 4*x^2 + I*4*y^2;
end:
`f(x,y) ` = f(x,y); ` `;
`At  z = 1 + 2i: `;
`f(1,2) ` = f(1,2);

`f(x,y) ` = 4*x^2+4*I*y^2

` `

`At z = 1 + 2i: `

`f(1,2) ` = 4+16*I

Method 2. Make  f(z)  a function of  z .

> F:='F': w:='w': z:='z': Z:='Z':
w := subs({x=(Z+conjugate(Z))/2, y=(Z-conjugate(Z))/(2*I)},f(x,y)):
F := z -> subs(Z=z, expand(w)):
`f(x,y) ` = f(x,y);
`F(z) ` = F(z); ` `;
`At  z = 1 + 2i: `;
`F(1 + I 2) ` = F(1+I*2); ` `;
`F(1 + I 2) ` = evalc(F(1+I*2));

`f(x,y) ` = 4*x^2+4*I*y^2

`F(z) ` = z^2+2*conjugate(z)*z+conjugate(z)^2-I*z^2+2*I*conjugate(z)*z-I*conjugate(z)^2

` `

`At z = 1 + 2i: `

`F(1 + I 2) ` = (1+7*I)+(-2+6*I)*conjugate(1+2*I)+conjugate(1+2*I)^2-I*conjugate(1+2*I)^2

` `

`F(1 + I 2) ` = 4+16*I

Example 2.5, Page 51.   Express  f(z) = z^5+4*z^2-6  in the polar coordinate form.  

Method 1. Make  f(x, y)  a function of two real variables  x, y .

> F:='F': x:='x': y:='y': z:='z':
F := proc(z)
 local w;
 w := z^5 + 4*z^2 - 6;
end:
`F(z) ` = z^5 + 4*z^2 - 6;
`F(x + I y) ` = F(x + I*y);` `;
`At  z = 1 + i: `;
`F(1 + I) ` = F(1 + I);

`F(z) ` = z^5+4*z^2-6

`F(x + I y) ` = (x+I*y)^5+4*(x+I*y)^2-6

` `

`At z = 1 + i: `

`F(1 + I) ` = -10+4*I

Method 2. Make  f(z)  a function of  z .

> f:='f': r:='r': t:='t': z:='z':
f := proc(r,t)
 local w;
 w := subs({z^2=r^2*cos(2*t) + I*r^2*sin(2*t),
   z^5=r^5*cos(5*t) + I*r^5*sin(5*t)}, F(z));
end:
`F(z) ` = z^5 + 4*z^2 - 6;
`f(r,t) ` = f(r,t);  ` `;
`At  z = 1 + i: `;
`f(sqrt(2),Pi/4) ` = f(sqrt(2),Pi/4);

`F(z) ` = z^5+4*z^2-6

`f(r,t) ` = r^5*cos(5*t)+I*r^5*sin(5*t)+4*r^2*cos(2*t)+4*I*r^2*sin(2*t)-6

` `

`At z = 1 + i: `

`f(sqrt(2),Pi/4) ` = -10+4*I

>

End of Section 2.1.