Symbolics - Maple Help

All Products Maple MapleSim

Home : Support : Online Help : System : Information : Updates : Maple 9 : Symbolics

Enhancements to Symbolic Capabilities in Maple 9

Maple 9 includes a number of enhancements to its symbolic capabilities, including updates to the special functions, differential and algebraic equation solvers, and integration.

Integration

Differential Equations (DEs)

FunctionAdvisor Command

Conversion Routines for Mathematical Functions

Special Functions

Series of Mathematical Functions

assuming Facility

Simplification

Solving Algebraic and Recurrence Equations

Miscellaneous

Integration

•	The new AllSolutions option is available for int. This option causes the int command to work harder when attempting to calculate a definite integral and return the entire set of solutions. For more information, see int.

>	int(1/x, x=a..2);

Warning, unable to determine if 0 is between a and 2; try to use assumptions or use the AllSolutions option

$int (\frac{1}{x}, x = a .. 2)$

(1)

>	r := int(1/x, x=a..2, 'AllSolutions');

$r ≔ \{\begin{array}{c} undefined & a < 0 \\ \infty & a = 0 \\ - \ln (a) + \ln (2) & 0 < a \end{array}$

(2)

>	r assuming a > 0;

$- \ln (a) + \ln (2)$

(3)

>	r assuming a < 0;

$undefined$

(4)

>	int(abs(sin(x)), x=0..2Pim) assuming m::integer;

$int (abs (\sin (x)), x = 0 .. 2 π m)$

(5)

>	int(abs(sin(x)), x=0..2Pim, 'AllSolutions') assuming m::integer;

$4 m$

(6)

>	int(1/x, x=a..b);

Warning, unable to determine if 0 is between a and b; try to use assumptions or use the AllSolutions option

$int (\frac{1}{x}, x = a .. b)$

(7)

>	int(1/x, x=a..b) assuming a < b;

$\{\begin{array}{c} undefined & 0 < b \land a < 0 \\ - \ln (a) + \ln (b) & otherwise \end{array}$

(8)

Differential Equations (DEs)

Differential equation solving capabilities (for exact and numeric solutions) are greatly enhanced by new algorithms and an interactive interface for solving ODEs. To learn about the DE updates, including those related to the dsolve and pdsolve commands, see Updates to Differential Equation Solvers.

FunctionAdvisor Command

In addition to using mathematical functions computationally, you also need general information about their properties in Maple, for example, definitions, identities, integral forms, and series expansions. You can access this information directly from the Maple 9 prompt, using the new FunctionAdvisor command (and the related MathematicalFunctions package).

The main purpose of this command is to return information about the Maple mathematical language in a form that you can read and directly use in mathematical computations.

The FunctionAdvisor command provides information on the whole set of mathematical functions implemented in the Maple system and also on the following function classes.

trig,	trigh,	arctrig,	arctrigh,
elementary,	GAMMA_related,	Psi_related,	Kelvin,
Airy,	Hankel,	Bessel_related,	`0F1`,
Ei_related,	erf_related,	Kummer,	Whittaker,
Cylinder,	`1F1`,	orthogonal_polynomials,	Elliptic_related,
Legendre,	Chebyshev,	`2F1`,	Lommel,
Struve_related,	hypergeometric,	Jacobi_related,	Elliptic_doubly_periodic,
Weierstrass_related,	Zeta_related,	Other

For each mathematical function or function class, when applicable, the FunctionAdvisor command provides information on the following topics.

analytic_extension	asymptotic_expansion	branch_cuts	branch_points
calling_sequence	class_members	classify_function	DE
definition	describe	differentiation_rule	display
function_classes	identities	integral_form	known_functions
plot	relate	series	singularities
special_values	specialize	sum_form	synonyms
table	topics

Examples

When called without arguments, FunctionAdvisor returns information on how to use the command.

>	FunctionAdvisor();

The usage is as follows:
    > FunctionAdvisor( topic, function, ... );
where 'topic' indicates the subject on which advice is required, 'function' is the name of a Maple function, and '...' represents possible additional input depending on the 'topic' chosen. To list the possible topics:
    > FunctionAdvisor( topics );
A short form usage,
    > FunctionAdvisor( function );
with just the name of the function is also available and displays a summary of information about the function.

>	FunctionAdvisor(topics);

The topics on which information is available are:

$[DE, analytic_extension, asymptotic_expansion, branch_cuts, branch_points, calling_sequence, class_members, classify_function, definition, describe, differentiation_rule, function_classes, identities, integral_form, known_functions, periodicity, plot, relate, required_assumptions, series, singularities, special_values, specialize, sum_form, symmetries, synonyms, table]$

(9)

FunctionAdvisor can return basic information, for example, the names for the Bessel functions in the Maple system,

>	FunctionAdvisor(bess);

* Partial match of "bess" against topic "Bessel_related".
The 14 functions in the "Bessel_related" class are:

$[AiryAi, AiryBi, BesselI, BesselJ, BesselK, BesselY, HankelH1, HankelH2, KelvinBei, KelvinBer, KelvinHei, KelvinHer, KelvinKei, KelvinKer]$

(10)

>	FunctionAdvisor(describe, BesselK);

$BesselK = Modified Bessel function of the second kind$

(11)

as well as the complicated relationships between mathematical functions and their identities, which are computed using a knowledge database and related algorithms.

>	FunctionAdvisor( identities, BesselK ); # see also ?convert,to_special_function

$[[BesselK (a, I z) = - \frac{π BesselY (a, z)}{2 I^{a}} + \frac{BesselJ (a, z) (\ln (z) - \ln (I z))}{I^{a}}, a :: integer], [BesselK (a, I z) = - \frac{π z^{a} BesselY (a, z)}{2 {(I z)}^{a}} + \frac{π BesselJ (a, z) (- \frac{{(I z)}^{a}}{z^{a}} + \frac{z^{a} \cos (a π)}{{(I z)}^{a}}) \csc (a π)}{2}, a :: (\neg integer)], [BesselK (a, - z) = {(−1)}^{a} BesselK (a, z) + BesselI (a, z) (\ln (z) - \ln (- z)), a :: integer], [BesselK (a, - z) = \frac{z^{a} BesselK (a, z)}{{(- z)}^{a}} + \frac{π (\frac{z^{a}}{{(- z)}^{a}} - \frac{{(- z)}^{a}}{z^{a}}) BesselI (a, z) \csc (a π)}{2}, a :: (\neg integer)], [BesselK (a, b {(c z^{q})}^{p}) = \frac{{(b c^{p} z^{p q})}^{a} BesselK (a, b c^{p} z^{p q})}{{(b {(c z^{q})}^{p})}^{a}} - \frac{π \csc (a π) BesselI (a, b c^{p} z^{p q}) (\frac{{(b {(c z^{q})}^{p})}^{a}}{{(b c^{p} z^{p q})}^{a}} - \frac{{(b c^{p} z^{p q})}^{a}}{{(b {(c z^{q})}^{p})}^{a}})}{2}, a :: (\neg integer) \land (2 p) :: integer], [BesselK (a, b {(c z^{q})}^{p}) = {(\frac{{(c z^{q})}^{p}}{c^{p} z^{p q}})}^{a} (BesselK (a, b c^{p} z^{p q}) - {(−1)}^{a} BesselI (a, b c^{p} z^{p q}) (\ln (b {(c z^{q})}^{p}) - \ln (b c^{p} z^{p q}))), a :: integer \land (2 p) :: integer], BesselK (a, z) = \frac{2 (a - 1) BesselK (a - 1, z)}{z} + BesselK (a - 2, z), BesselK (a, z) = - \frac{2 (a + 1) BesselK (a + 1, z)}{z} + BesselK (a + 2, z)]$

(12)

>	FunctionAdvisor( special_values, sec );

$[\sec (\frac{π}{6}) = \frac{2 \sqrt{3}}{3}, \sec (\frac{π}{4}) = \sqrt{2}, \sec (\frac{π}{3}) = 2, \sec (\infty) = undefined, \sec (\infty I) = 0, [\sec (π n) = −1, n :: odd], [\sec (π n) = 1, n :: even], [\sec (\frac{π n}{2}) = \infty + \infty I, n :: odd]]$

(13)

>	FunctionAdvisor( sum_form, tan );

$[\tan (z) = \sum_{_k1 = 1}^{\infty} \frac{bernoulli (2_k1) {(−1)}^{_k1} z^{2_k1 - 1} (4^{_k1} - 16^{_k1})}{Γ (2_k1 + 1)}, |z| < \frac{π}{2}]$

(14)

>	FunctionAdvisor( integral_form, Beta );

$[Β (x, y) = Int ({_k1}^{x - 1} {(1 -_k1)}^{y - 1},_k1 = 0 .. 1), And (0 < &real; (x), 0 < &real; (y))]$

(15)

>	FunctionAdvisor( relate, sin, WhittakerM );

$\sin (z) = - \frac{I}{2} WhittakerM (0, \frac{1}{2}, 2 I z)$

(16)

>	FunctionAdvisor( specialize, HermiteH, KummerU );

$[HermiteH (a, z) = 2^{a} KummerU (- \frac{a}{2}, \frac{1}{2}, z^{2}), 0 < ℜ (z) \lor (ℜ (z) = 0 \land 0 < ℑ (z))]$

(17)

A table with a summary of information about the inverse cotangent function:

>	arccot_info := FunctionAdvisor(table, arccot, quiet): # raw table of information

>	FunctionAdvisor(display, arccot_info); # ordered display

$describe = (arccot = inverse cotangent function)$

$definition = [arccot (z) = \frac{π}{2} - \frac{I (\ln (1 - I z) - \ln (1 + I z))}{2}, with no restrictions on (z)]$

$classify_function = (arctrig, elementary)$

$symmetries = [arccot (- z) = π - arccot (z), [arccot (\overset{&conjugate0;}{z}) = \overset{&conjugate0;}{arccot (z)}, not (z \in ComplexRange (- \infty I, −I) or z \in ComplexRange (I, \infty I))]]$

$periodicity = [arccot (z), No periodicity]$

$singularities = [arccot (z), z = \infty + \infty I]$

$branch_points = [arccot (z), z \in [−I, I]]$

$branch_cuts = [arccot (z), z \in ComplexRange (- \infty I, −I) \lor z \in ComplexRange (I, \infty I)]$

$special_values = [arccot (−1) = \frac{3 π}{4}, arccot (- \frac{\sqrt{3}}{3}) = \frac{2 π}{3}, arccot (- \sqrt{3}) = \frac{5 π}{6}, arccot (0) = \frac{π}{2}, arccot (\sqrt{3}) = \frac{π}{6}, arccot (\frac{\sqrt{3}}{3}) = \frac{π}{3}, arccot (1) = \frac{π}{4}, arccot (\infty) = 0, arccot (- \infty) = π]$

$identities = [\cot (arccot (z)) = z, \cot (arccot (z) + arccot (y)) = \frac{z y - 1}{z + y}]$

$sum_form = [arccot (z) = \sum_{_k1 = 0}^{\infty} (- \frac{z ({(I z)}^{_k1} + {(−I z)}^{_k1})}{2_k1 + 2}) + \frac{π}{2}, And (abs (z) < 1)]$

$series = (series (arccot (z), z, 4) = \frac{π}{2} - z + \frac{1}{3} z^{3} + O (z^{5}))$

$asymptotic_expansion = (asympt (arccot (z), z, 4) = \frac{1}{z} - \frac{1}{3 z^{3}} + O (\frac{1}{z^{5}}))$

$integral_form = [arccot (z) = Int (- \frac{\frac{1}{2} I}{_k1},_k1 = 1 + I z .. 1 - I z) + \frac{1}{2} π, with no restrictions on (z)]$

$differentiation_rule = (Diff (arccot (z), z) = - \frac{1}{z^{2} + 1}, Diff (arccot (z), z &dollar; n) = piecewise (n = 0, arccot (z), - 2^{n - 1} MeijerG ([[0, 0, \frac{1}{2}], []], [[0], [\frac{1}{2} n - \frac{1}{2}, \frac{1}{2} n]], z^{2}) z^{1 - n}))$

$DE = [f (z) = arccot (z), [\frac{&DifferentialD;}{&DifferentialD; z} f (z) = - \frac{1}{z^{2} + 1}]]$

(18)

Conversion Routines for Mathematical Functions

This network of conversions between mathematical functions was introduced in Maple 8. In Maple 9, the number of possible connections paths is almost tripled leading to many more relationships. Also, fourteen new conversions are available in the library, including conversions to EllipticF, InverseJacobiAM, InverseJacobiSN, JacobiAM, JacobiCN, JacobiDN, JacobiSN, Li, LommelS1, LommelS2, Psi, Si, Ssi, and Zeta. Two additional new conversion routines, to integral form and to sum form are also available, so that it is possible to obtain a sum or integral representation for most mathematical functions.

Examples

New function conversions:

>	harmonic(z,n);

$harmonic (z, n)$

(19)

>	(19) = convert((19), Psi) assuming n::posint;

$harmonic (z, n) = \frac{{(−1)}^{n} (Ψ (n - 1, 1) - Ψ (n - 1, z + 1))}{(n - 1)!}$

(20)

>	(19) = convert((19), Zeta);

$harmonic (z, n) = ζ (n) - ζ (0, n, z + 1)$

(21)

>	(19) = convert((19), LerchPhi);

$harmonic (z, n) = ζ (n) - LerchPhi (1, n, z + 1)$

(22)

>	convert(InverseJacobiAM(z,k), EllipticF) assuming And(-1/2Pi < Re(z),Re(z) < 1/2Pi);

$EllipticF (\sin (z), k)$

(23)

>	InverseJacobiSC(z,k) = convert(InverseJacobiSC(z,k), InverseJacobiSN);

$InverseJacobiSC (z, k) = −I InverseJacobiSN (I z, \sqrt{- k^{2} + 1})$

(24)

Sum and integral representations for the trigonometric functions:

>	trigonometric_functions := FunctionAdvisor( trig )(z);

The 6 functions in the "trig" class are:

$trigonometric_functions ≔ [\cos (z), \cot (z), \csc (z), \sec (z), \sin (z), \tan (z)]$

(25)

>	map(f -> f = convert(f,Sum), trigonometric_functions) assuming abs(z) < Pi/2;

$[\cos (z) = \sum_{_k1 = 0}^{\infty} \frac{{(−1)}^{_k1} z^{2_k1}}{(2_k1)!}, \cot (z) = \sum_{_k1 = 0}^{\infty} \frac{{(−1)}^{_k1} 2^{2_k1} bernoulli (2_k1) z^{2_k1 - 1}}{(2_k1)!}, \csc (z) = \sum_{_k1 = 0}^{\infty} (- \frac{2 (2^{2_k1 - 1} - 1) bernoulli (2_k1) z^{2_k1 - 1} {(−1)}^{_k1}}{(2_k1)!}), \sec (z) = \sum_{_k1 = 0}^{\infty} \frac{{(−1)}^{_k1} euler (2_k1) z^{2_k1}}{(2_k1)!}, \sin (z) = \sum_{_k1 = 0}^{\infty} \frac{{(−1)}^{_k1} z^{2_k1 + 1}}{(2_k1 + 1)!}, \tan (z) = \sum_{_k1 = 1}^{\infty} \frac{bernoulli (2_k1) {(−1)}^{_k1} z^{2_k1 - 1} (4^{_k1} - 16^{_k1})}{Γ (2_k1 + 1)}]$

(26)

>	map(f -> f = convert(f,Int), [sin, cos](z) );

$[\sin (z) = z (Int (\exp (2 I_t1 z),_t1 = 0 .. 1)) \exp (- I z), \cos (z) = - \frac{1}{2} I (2 z + π) (Int (\exp (I_t1 (2 z + π)),_t1 = 0 .. 1)) \exp (- I z)]$

(27)

>	tan(z) = convert(tan(z), Int) assuming z in RealRange(Open(0), Open(Pi/2));

$\tan (z) = \frac{2 (Int (\frac{{_k1}^{\frac{2 z}{π}} - 1}{{_k1}^{2} - 1},_k1 = 0 .. \infty))}{π}$

(28)

>	trigonometric_functions := FunctionAdvisor( trig )(z);

The 6 functions in the "trig" class are:

$trigonometric_functions ≔ [\cos (z), \cot (z), \csc (z), \sec (z), \sin (z), \tan (z)]$

(29)

>	map(f -> f = convert(f,Sum), trigonometric_functions) assuming abs(z) < Pi/2;

(30)

>	map(f -> f = convert(f,Int), [sin, cos](z) );

$[\sin (z) = z (Int (\exp (2 I_t1 z),_t1 = 0 .. 1)) \exp (- I z), \cos (z) = - \frac{1}{2} I (2 z + π) (Int (\exp (I_t1 (2 z + π)),_t1 = 0 .. 1)) \exp (- I z)]$

(31)

>	tan(z) = convert(tan(z), Int) assuming z in RealRange(Open(0), Open(Pi/2));

$\tan (z) = \frac{2 (Int (\frac{{_k1}^{\frac{2 z}{π}} - 1}{{_k1}^{2} - 1},_k1 = 0 .. \infty))}{π}$

(32)

Special Functions

Family of Inverse Jacobi Functions

In Maple 9, the family of twelve inverse Jacobi functions is available. These functions are represented by the InverseJacobiPQ commands where P and Q are any two of {C, D, N, S}. The InverseJacobiAM function represents the normal trigonometric form of the Elliptic integral of the first kind (see 8.111 in Gradshteyn and Ryzhik. Table of Integrals Series and Products. 5th ed. Academic Press).

Example

>	FunctionAdvisor(definition, InverseJacobiAM);

$[InverseJacobiAM (φ, k) = Int (\frac{1}{\sqrt{1 - k^{2} {\sin (_θ1)}^{2}}},_θ1 = 0 .. φ), with no restrictions on (φ, k)]$

(33)

>	FunctionAdvisor(special_values, InverseJacobiAM);

$[InverseJacobiAM (- φ, k) = - InverseJacobiAM (φ, k), InverseJacobiAM (φ, - k) = InverseJacobiAM (φ, k), InverseJacobiAM (0, k) = 0, InverseJacobiAM (φ, 0) = φ, [InverseJacobiAM (\frac{n π}{2}, k) = n EllipticK (k), n :: integer], [InverseJacobiAM (φ, k) = \ln (\sec (φ) + \tan (φ)), |ℜ (φ)| < \frac{π}{2} \land k \in \{−1, 1\}], [InverseJacobiAM (φ, k) = 0, k \in \{\infty, - \infty\}], [InverseJacobiAM (\infty I, k) = EllipticK (k) - \frac{EllipticK (\frac{1}{k})}{\sqrt{k}}, k^{2} \in (0, 1)]]$

(34)

>	InverseJacobiCN(z,k) assuming z = -1;

$2 EllipticK (k)$

(35)

>	InverseJacobiSN(z,k) assuming z = infinity, k^2 > 1;

$EllipticK (k) - \frac{EllipticK (\sqrt{\frac{1}{k^{2}}})}{k}$

(36)

>	JacobiDN( InverseJacobiDN(z,k), k );

$z$

(37)

Mathieu Functions

In Maple 9, the family of Mathieu functions is available. These functions are the solutions of Mathieu's equation:

$y'' + (a - 2 q \cos (2 x)) y = 0$

and their related support functions. Included are the 2*Pi-periodic solutions ( $MathieuCE$ and $MathieuSE$ ), the general even and odd solutions ( $MathieuC$ and $MathieuS$ ), the Floquet solution ( $MathieuFloquet$ ), and the first derivatives of all of these (higher derivatives can be represented in terms of the functions and their first derivatives using the differential equation).

Maple also implements the characteristic value functions ( $MathieuA$ and $MathieuB$ ) and the characteristic exponent function ( $MathieuExponent$ ).

For more information, see Mathieu.

Analytic Extension for the Exponential Integral Function

In Maple 9, the exponential integral function accepts non-real arguments and a non-integer first argument in the two-argument calling sequence. The analytic extension in Maple is:

>	FunctionAdvisor( analytic_extension, Ei(n,z) );

${Ei}_{n} (z) = z^{n - 1} Γ (1 - n, z)$

(38)

which extends the classical definition (valid only for $n$ non-negative integer and $0 < ℜ (z)$ ):

>	Ei(n, z) = convert(Ei(n, z), Int) assuming n::nonnegint, Re(z) > 0;

$Ei (n, z) = Int (\exp (- z_k1) {_k1}^{- n},_k1 = 1 .. \infty)$

(39)

The classical definition for the one-argument exponential integral is a Cauchy Principal Value integral, defined for real arguments x.

>	Ei(z) = convert(Ei(z), Int) assuming z::real;

$Ei (z) = Int (\frac{\exp (_k1)}{_k1},_k1 = - \infty .. z, CauchyPrincipalValue)$

(40)

This classical definition is extended to the entire complex plane using:

>	FunctionAdvisor( analytic_extension, Ei(z) );

$Ei (z) = γ - \frac{\ln (\frac{1}{z})}{2} + \frac{\ln (z)}{2} + z hypergeom ([1, 1], [2, 2], z)$

(41)

The Generalized harmonic Function

The harmonic function, representing the harmonic numbers, is generalized to accept two arguments, but still accepts the one-argument calling sequence. The definition of $harmonic (z)$ is:

>	FunctionAdvisor( definition, harmonic(z) );

$[harmonic (z) = Ψ (z + 1) + γ, with no restrictions on (z)]$

(42)

and the generalized harmonic function is defined by:

>	FunctionAdvisor( definition, harmonic(z,n) );

$[harmonic (z, n) = ζ (n) - ζ (0, n, z + 1), with no restrictions on (z, n)]$

(43)

where:

>	harmonic(z,n) assuming n = 1;

$harmonic (z)$

(44)

Computing under Assumptions on the Command Parameters

In Maple 9, more commands take assumptions into account (see assuming), including: doublefactorial, EllipticModulus, EllipticNome, GaussAGM, harmonic, pochhammer, LerchPhi, Zeta, the two Lommel commands, and the twenty-six Jacobi and InverseJacobi commands.

doublefactorial Command

>	doublefactorial(n) assuming n > 0, n::even;

$2^{\frac{n}{2}} (\frac{n}{2})!$

(45)

>	doublefactorial(n) assuming n > 0, n::odd;

$\frac{n!}{2^{\frac{n}{2} - \frac{1}{2}} (\frac{n}{2} - \frac{1}{2})!}$

(46)

GaussAGM Command

>	GaussAGM(a,b) assuming a = 0;

$0$

(47)

>	GaussAGM(a,b) assuming a = b;

$a$

(48)

EllipticNome and EllipticModulus Commands

>	EllipticNome(k) assuming k = 1;

$1$

(49)

>	EllipticNome(k) assuming k^2 = 1/2;

${&ExponentialE;}^{- π}$

(50)

>	EllipticModulus(q) assuming q = exp(-Pi);

$\frac{\sqrt{2}}{2}$

(51)

LerchPhi Command

>	LerchPhi(z,a,v) assuming z=1;

$z ζ (0, a, v)$

(52)

>	LerchPhi(z,a,v) assuming v=1;

$\frac{v polylog (a, z)}{z}$

(53)

Lommel Commands

>	LommelS2(mu,nu,z) assuming mu = nu + 1;

$z^{ν}$

(54)

>	LommelS1(mu,nu,z) assuming mu = nu;

$Γ (\frac{1}{2} + ν) \sqrt{π} 2^{ν - 1} StruveH (ν, z)$

(55)

>	LommelS1(mu,nu,z) assuming mu = 0;

$\frac{π (\tan (\frac{ν π}{2}) AngerJ (ν, z) - WeberE (ν, z))}{2}$

(56)

Jacobi Commands

>	JacobiZeta(z,k) assuming (2*z/Pi)::integer;

$JacobiZeta (z, k)$

(57)

>	JacobiAM(z,k) assuming k = 1;

$2 \arctan ({&ExponentialE;}^{z}) - \frac{π}{2}$

(58)

>	JacobiCN(z,k) assuming k = 0;

$\cos (z)$

(59)

>	JacobiSN(z,k) assuming k = 0;

$\sin (z)$

(60)

InverseJacobi Commands

>	InverseJacobiCN(z,k) assuming k=1;

$arcsech (z)$

(61)

>	InverseJacobiSN(z,k) assuming z=1;

$EllipticK (k)$

(62)

>	InverseJacobiAM(z,k) assuming z = n/2*Pi, n::integer;

$\frac{2 z EllipticK (k)}{π}$

(63)

pochhammer Command

>	pochhammer(a,b) assuming a=-1, b=-2;

$\frac{{(−1)}^{b} Γ (1 - a)}{Γ (1 - a - b)}$

(64)

>	pochhammer(a,b) assuming b::complex(numeric), csgn(b)=-1;

$\frac{1}{pochhammer (a + b, - b)}$

(65)

Zeta Command

>	Zeta(n,z,q) assuming q=1;

$ζ (n, z)$

(66)

>	Zeta(n,z,q) assuming n = 0, z::integer, z > 1;

$\frac{{(−1)}^{z} Ψ (z - 1, q)}{(z - 1)!}$

(67)

>	Zeta(n,z,q) assuming n = 0, z::integer, z < 1;

$- \frac{bernoulli (1 - z, q)}{1 - z}$

(68)

Series of Mathematical Functions

The Maple 9 series command can compute series for various new functions: EllipticNome, GaussAGM, ChebyshevT, ChebyshevU, and the four JacobiTheta functions.

Examples

>	series( EllipticNome(k), k );

$\frac{1}{16} k^{2} + \frac{1}{32} k^{4} + O (k^{6})$

(69)

>	series( JacobiTheta1(z,q), q );

$2 q^{\frac{1}{4}} \sin (z) - 2 q^{\frac{9}{4}} \sin (3 z) + O (q^{\frac{25}{4}})$

(70)

>	series( JacobiTheta4(z,q), q );

$1 - 2 \cos (2 z) q + 2 \cos (4 z) q^{4} + O (q^{9})$

(71)

>	series( ChebyshevT(5,z), z );

$5 z - 20 z^{3} + 16 z^{5}$

(72)

>	series( ChebyshevT(a,z), z, 4 );

$\cos (\frac{a π}{2}) + \sin (\frac{a π}{2}) a z - \frac{1}{2} \cos (\frac{a π}{2}) a^{2} z^{2} - \sin (\frac{a π}{2}) (- \frac{1}{6} a + \frac{1}{6} a^{3}) z^{3} + O (z^{4})$

(73)

>	series( ChebyshevU(a,z), z, 3 );

$\cos (\frac{a π}{2}) - \sin (\frac{a π}{2}) (- a - 1) z + (\frac{\cos (\frac{a π}{2})}{2} - \frac{{(- a - 1)}^{2} \cos (\frac{a π}{2})}{2}) z^{2} + O (z^{3})$

(74)

>	series( GaussAGM(x,y), x, 3 );

$\frac{π y}{2 (2 \ln (2) - \ln (\frac{x}{y}))} - \frac{1}{8} \frac{π (- 1 + 2 \ln (2) - \ln (\frac{x}{y}))}{y {(2 \ln (2) - \ln (\frac{x}{y}))}^{2}} x^{2} + O (x^{3})$

(75)

In Maple 9, the series command can compute series expansions in various new situations for some functions, including LegendreP, LegendreQ, MeijerG, GegenbauerC, JacobiP, erf, and the four Bessel functions.

Examples

>	series( LegendreP(-1/2,1/4,-(z+1)/(z-1)), z, 4 );

$\frac{1}{Γ (\frac{3}{4}) z^{\frac{1}{8}}} - \frac{z^{\frac{7}{8}}}{3 Γ (\frac{3}{4})} - \frac{5 z^{\frac{15}{8}}}{42 Γ (\frac{3}{4})} - \frac{31 z^{\frac{23}{8}}}{462 Γ (\frac{3}{4})} + O (z^{\frac{31}{8}})$

(76)

>	series( LegendreQ(-1/2,1/4,-(z+1)/(z-1)), z, 2 );

$\frac{(\frac{1}{8} + \frac{I}{8}) \sqrt{π} 2^{\frac{3}{4}} Γ (\frac{5}{8}) 4^{\frac{3}{4}}}{\csc (\frac{3 π}{8}) Γ (\frac{7}{8}) z^{\frac{1}{8}}} - \frac{(2 + 2 I) 2^{\frac{1}{4}} {Γ (\frac{3}{4})}^{2} Γ (\frac{7}{8}) z^{\frac{1}{8}}}{\sqrt{π} Γ (\frac{5}{8}) \csc (\frac{π}{8})} - \frac{(\frac{1}{24} + \frac{I}{24}) \sqrt{π} 2^{\frac{3}{4}} Γ (\frac{5}{8}) 4^{\frac{3}{4}} z^{\frac{7}{8}}}{\csc (\frac{3 π}{8}) Γ (\frac{7}{8})} + \frac{(\frac{2}{5} + \frac{2 I}{5}) 2^{\frac{1}{4}} {Γ (\frac{3}{4})}^{2} Γ (\frac{7}{8}) z^{\frac{9}{8}}}{\sqrt{π} Γ (\frac{5}{8}) \csc (\frac{π}{8})} + O (z^{\frac{15}{8}})$

(77)

>	series( MeijerG([[], []],[[-1/4], [1/4]],1/4*z^2), z );

$\frac{4^{\frac{1}{4}}}{\sqrt{π} \sqrt{z}} - \frac{4^{\frac{1}{4}} z^{\frac{3}{2}}}{2 \sqrt{π}} + \frac{4^{\frac{1}{4}} z^{\frac{7}{2}}}{24 \sqrt{π}} + O (z^{\frac{11}{2}})$

(78)

>	series( MeijerG([[1/2, 1/2], []],[[0], [-1/2]],-z^2), z);

$2 \sqrt{π} + \frac{1}{3} \sqrt{π} z^{2} + \frac{3}{20} \sqrt{π} z^{4} + O (z^{6})$

(79)

>	series( GegenbauerC(a,b,z), z, 2);

$GegenbauerC (a, b, 0) + (GegenbauerC (a - 1, b, 0) a + 2 GegenbauerC (a - 1, b, 0) b - GegenbauerC (a - 1, b, 0)) z + O (z^{2})$

(80)

>	series( BesselK(a,z+1), z, 2 );

$BesselK (a, 1) + (a BesselK (a, 1) - BesselK (a + 1, 1)) z + O (z^{2})$

(81)

>	series( polylog(a,z), z );

$z + \frac{1}{2^{a}} z^{2} + \frac{1}{3^{a}} z^{3} + \frac{1}{4^{a}} z^{4} + \frac{1}{5^{a}} z^{5} + O (z^{6})$

(82)

This expansion for polylog is valid only for $|z| < 1$ . You can verify this using the new FunctionAdvisor command.

>	FunctionAdvisor( sum_form, polylog );

$[polylog (a, z) = \sum_{_k1 = 1}^{\infty} \frac{z^{_k1}}{{_k1}^{a}}, |z| < 1], [polylog (a, z) = \frac{z}{2} + (\sum_{_k1 = - \infty}^{\infty} Γ (1 - a, 2 I_k1 π - \ln (z)) {(2 I_k1 π - \ln (z))}^{- 1 + a}), a :: posint], [polylog (a, z) = \frac{z}{2} + (\sum_{_k1 = - \infty}^{\infty} ((\sum_{_k2 = 0}^{\infty} \frac{{(- 2 I_k1 π + \ln (z))}^{_k2}}{{(2 I_k1 π - \ln (z))}^{- 1 + a} Γ (_k2 + 1) (-_k2 - 1 + a)}) + Γ (1 - a)) {(2 I_k1 π - \ln (z))}^{- 1 + a}), a :: (\neg posint)]$

(83)

Using the new MathematicalFunctions[Series] command, you can compute abstract series representations (not of type/series; see also series) for various functions by factoring out abstract powers and returning possible restrictions on the validity of the series expansion when applicable.

Example

>	with(MathematicalFunctions, Series);

$[Series]$

(84)

>	Series(polylog(a,z), z);

$z + \frac{1}{2^{a}} z^{2} + \frac{1}{3^{a}} z^{3} + \frac{1}{4^{a}} z^{4} + \frac{1}{5^{a}} z^{5} + O (z^{6}), And (abs (z) < 1)$

(85)

>	Series(GAMMA(a,z), z, 3);

$z^{a} (Γ (a) - \frac{1}{a} + \frac{1}{a + 1} z - \frac{1}{4 + 2 a} z^{2} + O (z^{3})), And (a :: (Not (nonposint)))$

(86)

>	Series(BesselJ(a,z), z);

$z^{a} (\frac{1}{2^{a} Γ (a + 1)} - \frac{1}{4} \frac{1}{2^{a} Γ (2 + a)} z^{2} + \frac{1}{32} \frac{1}{2^{a} Γ (3 + a)} z^{4} + O (z^{6})), And (a :: (Not (negint)))$

(87)

>	Series( LommelS1(a,b,z), z, 4 );

$z^{a} (\frac{1}{(a - b + 1) (a + b + 1)} z - \frac{1}{(a - b + 1) (a - b + 3) (a + b + 1) (a + b + 3)} z^{3} + O (z^{5})), (a + b) :: (\neg (negint \land odd)) \land (a - b) :: (\neg (negint \land odd))$

(88)

assuming Facility

In Maple 9, the assuming command accepts the optional additionally argument.

The expr assuming x1::prop1, x2::prop2, ... command evaluates the expression expr under the assumption(s) prop1, prop2, ... on the name(s) x1, x2, ..., respectively. By default, previously existing assumptions on x1, x2, ..., if any, are ignored when computing the result. To override this behavior, specify the 'additionally' argument to the right of assuming in the command.

Examples

>	assume(x < 1);

>	about(x); # display what is known about about x

Originally x, renamed x~:
is assumed to be: RealRange(-infinity,Open(1))

By default, the existing assumption $x < 1$ is ignored when computing using assuming.

>	is(1-x^2, positive) assuming x > -1;

$false$

(89)

Using additionally, the existing assumption on $x$ is taken into account when computing leading to:

>	is(1-x^2, positive) assuming additionally, x > -1;

$true$

(90)

Independent of whether you specify the additionally argument, any previously existing assumptions on the variables are preserved.

>	about(x); # same assumption as returned previously

Originally x, renamed x~:
is assumed to be: RealRange(-infinity,Open(1))

>	x := 'x': # remove assumptions on 'x'

Simplification

Trigonometric Functions

In Maple 9, the simplification of trigonometric functions is enhanced with new algorithms for trigonometric polynomials, and includes the following new behavior.

>	simplify( sin(x)^2 ); # 1 - cos(x)^2 in Maple 8

${\sin (x)}^{2}$

(91)

>	simplify( cos(x)^2 ); # works as in Maple 8

${\cos (x)}^{2}$

(92)

>	simplify( 1 - cos(x)^2 ); # 1 - cos(x)^2 in Maple 8

${\sin (x)}^{2}$

(93)

>	simplify( 1 - sin(x)^2 ); # works as in Maple 8

${\cos (x)}^{2}$

(94)

Powers and Radicals

The simplify command returns better results for expressions containing radicals.

>	((-(x-1)/x)^(1/2)x((x+1)/x)^(1/2)a-b(1-x^2)^(1/2))/(1-x^2)^(1/2);

$\frac{\sqrt{- \frac{- 1 + x}{x}} x \sqrt{\frac{x + 1}{x}} a - b \sqrt{- x^{2} + 1}}{\sqrt{- x^{2} + 1}}$

(95)

>	simplify((95),power) assuming x > 1;

$a - b$

(96)

Special Functions

In Maple 9, the simplify command can better simplify more functions.

>	simplify(Ssi(z)+1/2*Pi - Si(z));

$0$

(97)

>	simplify(GegenbauerC(2,a,z)) assuming a=1;

$4 z^{2} - 1$

(98)

>	simplify(GegenbauerC(n,a,z)) assuming z=-1, n::nonnegint;

$\frac{{(−1)}^{n} Γ (2 a + n)}{Γ (2 a) Γ (n + 1)}$

(99)

Chebyshev functions:

>	simplify(ChebyshevT(a,z)) assuming z = 0;

$\cos (\frac{a π}{2})$

(100)

>	simplify(ChebyshevT(a,z)) assuming z = 1;

$1$

(101)

>	simplify(ChebyshevU(a,z)) assuming z = 1;

$a + 1$

(102)

>	simplify(ChebyshevU(a,z)) assuming a = -1/2;

$\frac{\sqrt{2}}{2 \sqrt{z + 1}}$

(103)

With the new functions in the InverseJacobiPQ family, new related simplification routines map the problem - when possible - into a simpler one in terms of InverseJacobiAM.

>	simplify(InverseJacobiDS(sec(1/2)*(1-k^2)^(1/2),k) - EllipticK(k));

$InverseJacobiAM (\frac{1}{2}, k)$

(104)

>	simplify(InverseJacobiCS(csch(1/2),k));

$−I InverseJacobiAM (\frac{I}{2}, \sqrt{- k^{2} + 1})$

(105)

Simplification of RootOf

There is a new routine for simplifying expressions that contain RootOf expressions in a non-polynomial manner.

>	zero := Phi(y(x),(y(x)+RootOf(Phi(y(x),(y(x)+x_Z)/_Z))x)/RootOf(Phi(y(x),(y(x)+x*_Z)/_Z)));

$zero ≔ Φ (y (x), \frac{y (x) + RootOf (Φ (y (x), \frac{y (x) + x_Z}{_Z})) x}{RootOf (Φ (y (x), \frac{y (x) + x_Z}{_Z}))})$

(106)

>	simplify(zero); # new output

$0$

(107)

Equate zero to a variable ZERO and remove one RootOf from this expression (see also DEtools/remove_RootOf).

>	normal( DEtools[remove_RootOf]( zero = ZERO ) );

$Φ (y (x), RootOf (- Φ (y (x),_Z) + ZERO)) = 0$

(108)

>	simplify((108)); # new output

$ZERO = 0$

(109)

>	sin(RootOf(sin(_Z)+_Z-_Z^3))+RootOf(sin(_Z)+_Z-_Z^3)-RootOf(sin(_Z)+_Z-_Z^3)^3;

$\sin (RootOf (- \sin (_Z) -_Z + {_Z}^{3})) + RootOf (- \sin (_Z) -_Z + {_Z}^{3}) - {RootOf (- \sin (_Z) -_Z + {_Z}^{3})}^{3}$

(110)

>	simplify((110),RootOf); # new output

$0$

(111)

Simplification of Constant Expressions and of the Size of Expressions

More elaborate simplification of constant expressions (see the new simplification of constant expressions help page):

>	ee := -1/2Iexp(I)Ei(1,I) - 1/2Ei(1,I)sin(1) + 1/2IEi(1,I)cos(1) - 1/2Ei(1,-I)sin(1) - 1/2IEi(1,-I)cos(1) + 1/2Iexp(-I)Ei(1,-I);

$ee ≔ - \frac{I {&ExponentialE;}^{I} {Ei}_{1} (I)}{2} - \frac{{Ei}_{1} (I) \sin (1)}{2} + \frac{I {Ei}_{1} (I) \cos (1)}{2} - \frac{{Ei}_{1} (−I) \sin (1)}{2} - \frac{I {Ei}_{1} (−I) \cos (1)}{2} + \frac{I {&ExponentialE;}^{−I} {Ei}_{1} (−I)}{2}$

(112)

>	simplify((112)); # using simplify(ee, constant) produces the same result faster

$0$

(113)

Regarding the size of an expression, see the new simplification of an expression size help page.

>	e2 := -3sin(x)^(1/2)cos(x)^2sin(x)^m + 3sin(x)^(1/2)cos(x)^2cos(x)^n + 4sin(x)^(1/2)cos(x)^4sin(x)^m - 4sin(x)^(1/2)cos(x)^4cos(x)^n;

$e2 ≔ - 3 \sqrt{\sin (x)} {\cos (x)}^{2} {\sin (x)}^{m} + 3 \sqrt{\sin (x)} {\cos (x)}^{2} {\cos (x)}^{n} + 4 \sqrt{\sin (x)} {\cos (x)}^{4} {\sin (x)}^{m} - 4 \sqrt{\sin (x)} {\cos (x)}^{4} {\cos (x)}^{n}$

(114)

>	simplify((114), size); # requires the extra argument 'size' to be specified

$- 4 ({\cos (x)}^{n} - {\sin (x)}^{m}) \sqrt{\sin (x)} ({\cos (x)}^{2} - \frac{3}{4}) {\cos (x)}^{2}$

(115)

Simplification of Dummy Variables

In Maple 9, expressions that contain subexpressions similar up to the dummy variable name, for example, as integration or summation variables in definite integrals or sums, can be simplified.

>	Int(f(x), x=a..b) - Int(f(y), y=a..b);

$Int (f (x), x = a .. b) - (Int (f (y), y = a .. b))$

(116)

>	simplify((116));

$0$

(117)

>	Limit(f(x), x=a) - Limit(f(y), y=a);

$(lim_{x \to a} f (x)) - (lim_{y \to a} f (y))$

(118)

>	simplify((118));

$0$

(119)

When dummy variables are present in Intat constructions, such as in differential equation solutions, simplify attempts to make the dummy variable names the same, when possible, leading to expressions with better manipulation properties. For example,

>	e1 := (-xIntat(exp(-Int(f(_b),_b))g(_b),_b = y(x))+exp(-Intat(f(_a),_a = y(x))))/x;

$\frac{- x Intat (\exp (- (Int (f (_b),_b))) g (_b),_b = y (x)) + \exp (- Intat (f (_a),_a = y (x)))}{x}$

(120)

The previous expression contains the dummy variables $_a$ and $_b$ ; simplify makes the names the same.

>	e2 := simplify(e1);

$\frac{- x Intat (\exp (- (Int (f (_a),_a))) g (_a),_a = y (x)) + \exp (- Intat (f (_a),_a = y (x)))}{x}$

(121)

The mathematical manipulation properties of $e2$ are better. For example, compare the success of factor with $e1$ and $e2$ .

>	factor(diff(e1,x)); # does not factor because the dummy variables are different

$- \frac{\exp (- Intat (f (_b),_b = y (x))) (diff (y (x), x)) g (y (x)) x^{2} + (diff (y (x), x)) f (y (x)) \exp (- Intat (f (_a),_a = y (x))) x + \exp (- Intat (f (_a),_a = y (x)))}{x^{2}}$

(122)

>	factor(diff(e2,x)); # factors

$- \frac{\exp (- Intat (f (_a),_a = y (x))) ((diff (y (x), x)) g (y (x)) x^{2} + (diff (y (x), x)) f (y (x)) x + 1)}{x^{2}}$

(123)

Solving Algebraic and Recurrence Equations

•	The solve command is extended to find parametric solutions of equations. If the variables for which to solve are functions of a free variable, solve returns parametric solutions in terms of that variable.

>	solve( u^2+v^2-1, {u(s)=-1,v(s)=0} );

$\{u = \frac{s^{2} - 1}{s^{2} + 1}, v = \frac{2 s}{s^{2} + 1}\}$

(124)

>	solve( x^x - y^y, {x(t),y(t)});

$\{x = {&ExponentialE;}^{\frac{t \ln (\frac{1}{t})}{t - 1}}, y = t {&ExponentialE;}^{\frac{t \ln (\frac{1}{t})}{t - 1}}\}$

(125)

•	In Maple 9, rsolve can search for series solutions of systems of recurrence equations using the LinearFunctionalSystems package. If the 'series' option is specified, rsolve finds formal series solution by using the LinearFunctionalSystems[SeriesSolution] command.

>	sys := {y(x)x^2+3y(x)x+2y(x)-2z(x)x^2-4z(x)x+z(x+1)x^2+z(x+1)x = 0, y(x+5)-z(x) = 0};

$sys ≔ \{y (x + 5) - z (x) = 0, y (x) x^{2} + 3 y (x) x + 2 y (x) - 2 z (x) x^{2} - 4 z (x) x + z (x + 1) x^{2} + z (x + 1) x = 0\}$

(126)

>	vars := {y(x), z(x)};

$vars ≔ \{y (x), z (x)\}$

(127)

>	Order := 2: sol := rsolve(sys,vars,'series');

$sol ≔ \{y (x) = \frac{11171256901 {_c}_{5}}{64} + \frac{202134809 {_c}_{4}}{16} - 1160265804390 {_c}_{10} - \frac{2101241187045 {_c}_{9}}{4} - 91956626685 {_c}_{8} - \frac{20248267725 {_c}_{7}}{4} + \frac{6211703225 {_c}_{6}}{8} + {_c}_{3} + x (\frac{84884655807 {_c}_{5}}{320} + \frac{695475963 {_c}_{4}}{80} - 3716103506346 {_c}_{10} - \frac{5262694938963 {_c}_{9}}{4} - 164157505659 {_c}_{8} - \frac{4935798315 {_c}_{7}}{4} + \frac{16465573215 {_c}_{6}}{8}) + O (x^{2}), z (x) = {_c}_{1} + {_c}_{2} - \frac{1586137831 {_c}_{4}}{8} + 56102335540020 {_c}_{10} + \frac{41273311696155 {_c}_{9}}{2} + 2753324557830 {_c}_{8} + \frac{100460135475 {_c}_{7}}{2} - \frac{127908744775 {_c}_{6}}{4} - \frac{147985008059 {_c}_{5}}{32} + 3 {_c}_{3} + x (- \frac{4720528435 {_c}_{6}}{8} - \frac{28346072083 {_c}_{5}}{320} - \frac{325292447 {_c}_{4}}{80} + 1024685474274 {_c}_{10} + \frac{1528239898647 {_c}_{9}}{4} + 52115239071 {_c}_{8} + \frac{4509246735 {_c}_{7}}{4}) + O (x^{2})\}$

(128)

Miscellaneous

Converting between Boolean Functions and Boolean Operators

A new convert(expr, boolean_function) facility converts, in a given expression, all boolean statements constructed using the operators and, or, not, xor, implies to equivalent boolean function constructions using the functions And, Or, Not. This conversion facility is of use, among others things, for:

- Avoiding the automatic simplification of boolean operators

- Allowing the read of the boolean statement with the order of execution and precedence of the operations made explicit with parentheses

Examples

Boolean statements constructed with operators are simplified automatically.

>	z <> 0 and (b-2a-2 = 0 or b-2a = 0);

$false$

(129)

The equivalent boolean function statement is not automatically simplified. In this example, right single quotes around the boolean operator statement are required when performing the conversion.

>	convert( 'z <> 0 and (b-2a-2 = 0 or b-2a = 0)', boolean_function );

$z \neq 0 \land (b - 2 a - 2 = 0 \lor b - 2 a = 0)$

(130)

This function representation permits further manipulations of the boolean statement without automatic simplification to false.

When using the boolean operators and, or, xor, implies, the precedence of the operations is not always obvious, for example:

>	a and b or c and d or e;

$a and b or c and d or e$

(131)

The order of execution and the precedence becomes explicit when converting to boolean functions.

>	convert((131), boolean_function);

$(a \land b) \lor (c \land d) \lor e$

(132)

>	a xor b implies c and d;

$a xor b \Rightarrow c and d$

(133)

>	convert((133), boolean_function);

$\neg ((a \land \neg b) \lor (\neg a \land b)) \lor (c \land d)$

(134)

Converting Complex Ranges to Real Ranges or Relations

In connection with the new functionality provided by the FunctionAdvisor command, two new related routines, to convert from Complex Ranges to Real Ranges and from Real or Complex Ranges to relations, are available.

>	z::ComplexRange(-1-I,1+I);

$z :: ComplexRange (−1 - I, 1 + I)$

(135)

>	convert( (135), RealRange );

$ℜ (z) :: [−1, 1], ℑ (z) :: [−1, 1]$

(136)

>	convert( (135), relation );

$−1 \leq ℜ (z) \land ℜ (z) \leq 1 \land −1 \leq ℑ (z) \land ℑ (z) \leq 1$

(137)

>	FunctionAdvisor( branch_cuts, arccot );

$[arccot (z), z \in ComplexRange (- \infty I, −I) \lor z \in ComplexRange (I, \infty I)]$

(138)

>	convert( (138), relation );

$[arccot (z), (ℜ (z) = 0 \land - \infty \leq ℑ (z) \land ℑ (z) \leq −1) \lor (ℜ (z) = 0 \land 1 \leq ℑ (z) \land ℑ (z) \leq \infty)]$

(139)

define

Two new procedures redefine and undefine (see undefine) are available. These are used to change the definition of a name defined using the define and definemore commands.

>	define( F, F( 0 ) = 1, F( x::nonunit(algebraic) + y::nonunit(algebraic) ) = F( x ) + F( y ) );

>	F( 2 * a + b );

$F (2 a) + F (b)$

(140)

>	redefine( F, [ F( 0 ) = 1, F( x::nonunit(algebraic) + y::nonunit(algebraic) ) = F( x ) + F( y ), F( a::nonunit(numeric) * b::nonunit(algebraic) ) = a * F( b ) ] );

>	F( 2 * a + b );

$2 F (a) + F (b)$

(141)

>	undefine( F );

>	F( 2 * a + b );

$F (2 a + b)$

(142)

Maple

Maple Add-Ons

MapleSim

MapleSim Add-Ons

システムズエンジニアリング

コンサルティングサービス

オンライン教育製品

教育利用

産業分野

自動車及び航空宇宙

ロボティクス

マシンデザイン
& 産業オートメーション

その他

アプリケーション

製品価格

購入

教育機関向け
学生ライセンス

Maplesoft Elite Maintenance (EMP)

サポート

製品のトレーニング

オンライン製品ヘルプ

Webセミナー
& イベント

出版物

コンテンツ Hub

事例とアプリケーション

コミュニティ

Maplesoftについて

メディアセンター

ユーザコミュニティ

お問合せ

Online Help

All Products Maple MapleSim

Maple

シンプルな操作性の高度数学ソフトウェア

Maple Add-Ons

MapleSim

先進的なシステムレベルモデリング

MapleSim Add-Ons

システムズエンジニアリング

コンサルティングサービス

オンライン教育製品

教育利用

産業分野

自動車及び航空宇宙

ロボティクス

マシンデザイン & 産業オートメーション

その他

アプリケーション

製品価格

購入

教育機関向け 学生ライセンス

Maplesoft Elite Maintenance (EMP)

サポート

製品のトレーニング

オンライン製品ヘルプ

Webセミナー & イベント

出版物

コンテンツ Hub

事例とアプリケーション

コミュニティ

Maplesoftについて

メディアセンター

ユーザコミュニティ

お問合せ

Online Help

All Products Maple MapleSim

マシンデザイン
& 産業オートメーション

教育機関向け
学生ライセンス

Webセミナー
& イベント