output = norm or peakfreq or list of these names.

checkstability = truefalse

The NormHinf command computes the $H_{\mathrm{\infty }}$ norm of a linear system sys, with relative accuracy eps. Both continuous-time and discrete-time systems, and both single-input single-output (SISO) and multiple-input multiple-output (MIMO) systems are supported.

The $H_{\mathrm{\infty }}$ norm provides a measure of the worst-case system gain, i.e., the largest factor by which any sinusoidal input is magnified by the system. For instance, the $H_{\mathrm{\infty }}$ norm of the transfer function G from w (disturbance input) to y (output) provides a measure of the worst-case influence of the noise w on the output y of an LTI system.

For a SISO linear system, the $H_{\mathrm{\infty }}$ norm is the maximum gain of the frequency response of the system. In an analogous way, for a MIMO linear system, the $H_{\mathrm{\infty }}$ norm is the maximum gain across all inputs and outputs of the system.

The $H_{\mathrm{\infty }}$ norm of $G$ equals the peak value on the Bode magnitude plot of $G$. It also equals the distance from the origin to the farthest point on the Nyquist plot of $G$.

The $H_{\mathrm{\infty }}$ norm is finite if and only if the transfer function $G$ is proper (degree of denominator greater than or equal to degree of numerator) and has no poles on the imaginary axis (continuous-time) or on the unit circle (discrete-time).

with( DynamicSystems ):

sys1 := TransferFunction(100/(s+5)):

PrintSystem(sys1);

$\left[\begin{array}{l}\mathbf{Transfer\; Function}\\ \mathrm{continuous}\\ \mathrm{1\; output(s);\; 1\; input(s)}\\ \mathrm{inputvariable}\=\left[\mathrm{u1}\left(s\right)\right]\\ \mathrm{outputvariable}\=\left[\mathrm{y1}\left(s\right)\right]\\ {\mathrm{tf}}_{1,1}\=\frac{100}{s+5}\end{array}\right.$

hinfnorm1 := NormHinf(sys1, 10^(-10));

$\mathrm{hinfnorm1}≔20.00000000$

MagnitudePlot(sys1, decibels = false, range = 0.001..100);

mag := MagnitudePlot(sys1, decibels = false, range = 0.001..100, output = data):

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔19.9999996000000$

sys2 := DiffEquation(diff(diff(x(t),t),t) = -10*x(t) - diff(x(t),t) + w(t), [w(t)], [x(t)]):

PrintSystem(sys2);

$\left[\begin{array}{l}\mathbf{Diff.\; Equation}\\ \mathrm{continuous}\\ \mathrm{1\; output(s);\; 1\; input(s)}\\ \mathrm{inputvariable}\=\left[w\left(t\right)\right]\\ \mathrm{outputvariable}\=\left[x\left(t\right)\right]\\ \mathrm{de}\=\left[\frac{{\ⅆ}^2}{\ⅆt^2}x\left(t\right)=-10x\left(t\right)-\frac{\ⅆ}{\ⅆt}x\left(t\right)+w\left(t\right)\right]\end{array}\right.$

hinfnorm2 := NormHinf(sys2, 'output' = [peakfreq, norm]);

$\mathrm{hinfnorm2}≔\left[3.08220698300548\,0.320256627866482\right]$

MagnitudePlot(sys2, decibels = false);

mag := MagnitudePlot(sys2, decibels = false, output = data):

member(max(mag(1..-1, 2..2)), mag(1..-1, 2..2), 'p'): fHinf := mag(p);

$\mathrm{fHinf}≔3.079785057$

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔0.320252649756933$

sys3 := StateSpace( <<0,0,-3>|<1,0,-4>|<0,1,-7>>, <<0,0,1>>, <<1>|<0>|<0>>, Matrix(1,1) ):

PrintSystem(sys3);

$\left[\begin{array}{l}\mathbf{State\; Space}\\ \mathrm{continuous}\\ \mathrm{1\; output(s);\; 1\; input(s);\; 3\; state(s)}\\ \mathrm{inputvariable}\&equals;\left[\mathrm{u1}\left(t\right)\right]\\ \mathrm{outputvariable}\&equals;\left[\mathrm{y1}\left(t\right)\right]\\ \mathrm{statevariable}\&equals;\left[\mathrm{x1}\left(t\right)\&comma;\mathrm{x2}\left(t\right)\&comma;\mathrm{x3}\left(t\right)\right]\\ \mathrm{a}\&equals;\left[\begin{array}{ccc}0& 1& 0\\ 0& 0& 1\\ \mathrm{-3}& \mathrm{-4}& \mathrm{-7}\end{array}\right]\\ \mathrm{b}\&equals;\left[\begin{array}{c}0\\ 0\\ 1\end{array}\right]\\ \mathrm{c}\&equals;\left[\begin{array}{ccc}1& 0& 0\end{array}\right]\\ \mathrm{d}\&equals;\left[\begin{array}{c}0\end{array}\right]\end{array}\right.$

hinfnorm3 := NormHinf(sys3, 'output' = [norm, peakfreq]);

$\mathrm{hinfnorm3}≔\left[0.451322261502234\&comma;0.559605319105211\right]$

MagnitudePlot(sys3, decibels = false);

mag := MagnitudePlot(sys3, decibels = false, output = data):

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔0.451320291397442$

member(Hinfgraph, mag(1..-1, 2..2), 'p'): fHinf := mag(p);

$\mathrm{fHinf}≔0.5590478459$

sys4 := TransferFunction(Matrix([[1/(s^3+s^2+5*s+2)],[s/(s^3+s^2+5*s+2)],[(s^2)/(s^3+s^2+5*s+2)]])):

PrintSystem(sys4);

$\left[\begin{array}{l}\mathbf{Transfer\; Function}\\ \mathrm{continuous}\\ \mathrm{3\; output(s);\; 1\; input(s)}\\ \mathrm{inputvariable}\&equals;\left[\mathrm{u1}\left(s\right)\right]\\ \mathrm{outputvariable}\&equals;\left[\mathrm{y1}\left(s\right)\&comma;\mathrm{y2}\left(s\right)\&comma;\mathrm{y3}\left(s\right)\right]\\ {\mathrm{tf}}_{1,1}\&equals;\frac{1}{s^3+s^2+5s+2}\\ {\mathrm{tf}}_{2,1}\&equals;\frac{s}{s^3+s^2+5s+2}\\ {\mathrm{tf}}_{3,1}\&equals;\frac{s^2}{s^3+s^2+5s+2}\end{array}\right.$

hinfnorm4 := NormHinf(sys4, 0.001, 'output' = [norm, peakfreq]);

$\mathrm{hinfnorm4}≔\left[1.89966130541915\&comma;2.180899209\right]$

MagnitudePlot(sys4, decibels = false);

mag := MagnitudePlot(sys4, decibels = false, output = data):

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔1.69438112239631$

member(Hinfgraph, mag[3](1..-1, 2..2), 'p'): fHinf := mag[3](p);

$\mathrm{fHinf}≔2.184166359$

sys5 := TransferFunction(Matrix([[1/(s^2+s+4), 0],[0, 1/(s^2+s+4)]]) ):

PrintSystem(sys5);

$\left[\begin{array}{l}\mathbf{Transfer\; Function}\\ \mathrm{continuous}\\ \mathrm{2\; output(s);\; 2\; input(s)}\\ \mathrm{inputvariable}\&equals;\left[\mathrm{u1}\left(s\right)\&comma;\mathrm{u2}\left(s\right)\right]\\ \mathrm{outputvariable}\&equals;\left[\mathrm{y1}\left(s\right)\&comma;\mathrm{y2}\left(s\right)\right]\\ {\mathrm{tf}}_{1,1}\&equals;\frac{1}{s^2+s+4}\\ {\mathrm{tf}}_{2,1}\&equals;0\\ {\mathrm{tf}}_{1,2}\&equals;0\\ {\mathrm{tf}}_{2,2}\&equals;\frac{1}{s^2+s+4}\end{array}\right.$

hinfnorm5 := NormHinf(sys5, 'output' = [norm, peakfreq]);

$\mathrm{hinfnorm5}≔\left[0.516398295858964\&comma;1.87082283018653\right]$

MagnitudePlot(sys5, decibels = false);

mag := MagnitudePlot(sys5, decibels = false, output = data):

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔0.516350854134402$

member(Hinfgraph, mag[1](1..-1, 2..2), 'p'): fHinf := mag[1](p);

$\mathrm{fHinf}≔1.863838004$

sys6 := StateSpace(Matrix([[0,1],[-25,-0.1]]),Matrix([[0],[1]]),Matrix([[1,0]]),Matrix([[0]])):

PrintSystem(sys6);

$\left[\begin{array}{l}\mathbf{State\; Space}\\ \mathrm{continuous}\\ \mathrm{1\; output(s);\; 1\; input(s);\; 2\; state(s)}\\ \mathrm{inputvariable}\&equals;\left[\mathrm{u1}\left(t\right)\right]\\ \mathrm{outputvariable}\&equals;\left[\mathrm{y1}\left(t\right)\right]\\ \mathrm{statevariable}\&equals;\left[\mathrm{x1}\left(t\right)\&comma;\mathrm{x2}\left(t\right)\right]\\ \mathrm{a}\&equals;\left[\begin{array}{cc}0& 1\\ \mathrm{-25}& \mathrm{-0.1}\end{array}\right]\\ \mathrm{b}\&equals;\left[\begin{array}{c}0\\ 1\end{array}\right]\\ \mathrm{c}\&equals;\left[\begin{array}{cc}1& 0\end{array}\right]\\ \mathrm{d}\&equals;\left[\begin{array}{c}0\end{array}\right]\end{array}\right.$

hinfnorm6 := NormHinf(sys6, 'output' = [norm, peakfreq]);

$\mathrm{hinfnorm6}≔\left[2.00010200760040\&comma;4.99949995099030\right]$

MagnitudePlot(sys6, decibels = false);

mag := MagnitudePlot(sys6, decibels = false, output = data):

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔1.99995097863956$

member(Hinfgraph, mag(1..-1, 2..2), 'p'): fHinf := mag(p);

$\mathrm{fHinf}≔5.000110374$

sys7 := TransferFunction(10*(2*z+1)/(10*z^2 + 2*z + 5), discrete, sampletime = 0.1):

PrintSystem(sys7);

$\left[\begin{array}{l}\mathbf{Transfer\; Function}\\ \mathrm{discrete;\; sampletime\; =\; .1}\\ \mathrm{1\; output(s);\; 1\; input(s)}\\ \mathrm{inputvariable}\&equals;\left[\mathrm{u1}\left(z\right)\right]\\ \mathrm{outputvariable}\&equals;\left[\mathrm{y1}\left(z\right)\right]\\ {\mathrm{tf}}_{1,1}\&equals;\frac{20z+10}{10z^2+2z+5}\end{array}\right.$

hinfnorm7 := NormHinf(sys7, 10^(-8), 'output' = [norm, peakfreq]);

$\mathrm{hinfnorm7}≔\left[4.28984428905026\&comma;16.6685073027065\right]$

MagnitudePlot(sys7, decibels = false, range = 0.01..Pi/sys7:-sampletime);

mag := MagnitudePlot(sys7, decibels = false, range = 0.01..Pi/sys7:-sampletime, output = data):

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔4.289843575$

member(Hinfgraph, mag(1..-1, 2..2), 'p'): fHinf := mag(p);

$\mathrm{fHinf}≔16.66285136$

sys8 := TransferFunction([5, -14.2, 14.4, -5],[5, -12.1, 10, -2.7], discrete, sampletime=0.5):

PrintSystem(sys8);

$\left[\begin{array}{l}\mathbf{Transfer\; Function}\\ \mathrm{discrete;\; sampletime\; =\; .5}\\ \mathrm{1\; output(s);\; 1\; input(s)}\\ \mathrm{inputvariable}\&equals;\left[\mathrm{u1}\left(z\right)\right]\\ \mathrm{outputvariable}\&equals;\left[\mathrm{y1}\left(z\right)\right]\\ {\mathrm{tf}}_{1,1}\&equals;\frac{5.z^3-14.20000000z^2+14.40000000z-5.}{5.z^3-12.10000000z^2+10.z-2.700000000}\end{array}\right.$

hinfnorm8 := NormHinf(sys8, 'output' = [norm, peakfreq]);

$\mathrm{hinfnorm8}≔\left[4.63571003774221\&comma;0.615651253991577\right]$

MagnitudePlot(sys8, decibels = false, range = 0.01..Pi/sys8:-sampletime);

mag := MagnitudePlot(sys8, decibels = false, range = 0.01..Pi/sys8:-sampletime, output = data):

Hinfgraph := max(mag(1..-1, 2..2));

$\mathrm{Hinfgraph}≔4.635634989$

member(Hinfgraph, mag(1..-1, 2..2), 'p'): fHinf := mag(p);

$\mathrm{fHinf}≔0.6152990634$

S. Boyd, V. Balakrishnan, P. Kabamba, On computing the $H_{\mathrm{\infty }}$ norm of a transfer matrix, 1988.

N. A. Bruinsma, M. Steinbuch, A fast algortihm to compute the $H_{\mathrm{\infty }}$-norm of a transfer function matrix, 1990.

The DynamicSystems[NormHinf] command was introduced in Maple 18.

For more information on Maple 18 changes, see Updates in Maple 18.