scaling

One of biased, unbiased, or none.  Default is none. scaling=biased computes $R_k=\frac{C_k}{n}$. scaling=unbiased scales each $C_k$ by $\frac{1}{n-k}$.

raw

If this option is given, the output is not normalized so that the first entry is 1 when scaling=unbiased or scaling=none.

For a discrete time series X, the AutoCorrelation command computes the autocorrelations $R_k=\frac{C_k}{C_0}$ where $C_k=\sum _{t=1}^{n-k}\left(X_t-\mathrm{\mu }\right)\left(X_{t+k}-\mathrm{\mu }\right)$ for $k=0..n-1$ and  $\mathrm{\mu }$ is the mean of X.

For efficiency, all of the lags are computed at once using a numerical discrete Fourier transform.  Therefore all data provided must have type realcons and all returned solutions are floating-point, even if the problem is specified with exact values.

Note: AutoCorrelation makes use of DiscreteTransforms[FourierTransform] and thus will work strictly in hardware precision, that is, its accuracy is independent of the setting of Digits.

For more time series related commands, see the TimeSeriesAnalysis package.

with(Statistics):

AutoCorrelation(<1,2,1,2,1,2,1,2>);

$\left[\begin{array}{c}1.\\ \mathrm{-0.875000000009056}\\ 0.750000000020185\\ \mathrm{-0.625000000014873}\\ 0.500000000015000\\ \mathrm{-0.375000000015127}\\ 0.250000000009815\\ \mathrm{-0.125000000020944}\end{array}\right]$

AutoCorrelation(<1,2,1,2,1,2,1,2>, 2);

$\left[\begin{array}{c}1.\\ \mathrm{-0.875000000009056}\\ 0.750000000020185\end{array}\right]$

AutoCorrelation(<1,2,1,2,1,2,1,2>, 0..2);

$\left[\begin{array}{c}1.\\ \mathrm{-0.875000000009056}\\ 0.750000000020185\end{array}\right]$

AutoCorrelation(<1,2,1,2,1,2,1,2>, 1..2);

$\left[\begin{array}{c}\mathrm{-0.875000000009056}\\ 0.750000000020185\end{array}\right]$

AutoCorrelation(<1,2,1,2,1,2,1,2>, 2, scaling=unbiased);

$\left[\begin{array}{c}1.\\ \mathrm{-1.00000000001035}\\ 1.00000000002691\end{array}\right]$

AutoCorrelation(<1,2,1,2,1,2,1,2>, 2, scaling=biased);

$\left[\begin{array}{c}0.0624999999981250\\ \mathrm{-0.0546874999989254}\\ 0.0468749999998553\end{array}\right]$

AutoCorrelation(<1,2,1,2,1,2,1,2>, 2, raw);

$\left[\begin{array}{c}0.499999999985000\\ \mathrm{-0.437499999991403}\\ 0.374999999998843\end{array}\right]$

t := TimeSeriesAnalysis:-TimeSeries([[1,2,1,2,1,2,1,2],[8,7,6,5,4,3,2,1]], header=["Sales", "Profits"], enddate="2012-01-01", frequency="monthly");

$t≔\left[\begin{array}{c}\mathrm{Time\; series}\\ \mathrm{Sales,\; Profits}\\ \mathrm{8\; rows\; of\; data:}\\ \mathrm{2011-06-01\; -\; 2012-01-01}\end{array}\right]$

AutoCorrelation(t[.., "Sales"], 2);

$\left[\begin{array}{c}1.\\ \mathrm{-0.875000000009056}\\ 0.750000000020185\end{array}\right]$

R := <seq((1/3*(evalf(sin(17.2*i)*cos(13.8*i)+1.17)+rand(0..1)()*2/3)), i=1..500)>:

LineChart(R, size=[0.5,"golden"]);

AutoCorrelationPlot(R, lags=100);

with(TimeSeriesAnalysis):

Data := Import( "datasets/sunspots.csv", base=datadir, output=Matrix );

tsData := TimeSeries( Data[265..310, 2] );

$\mathrm{tsData}≔\left[\begin{array}{c}\mathrm{Time\; series}\\ \mathrm{data\; set}\\ \mathrm{46\; rows\; of\; data:}\\ \mathrm{1974\; -\; 2019}\end{array}\right]$

S := AutoCorrelation(tsData);

AutoCorrelationPlot(GetData(tsData));

The Statistics[AutoCorrelation] command was introduced in Maple 15.

For more information on Maple 15 changes, see Updates in Maple 15.

The Statistics[AutoCorrelation] command was updated in Maple 2015.

The X parameter was updated in Maple 2015.