The DirectionalDiff(F,v,c) command, where F is a scalar function, computes the directional derivative of F at the location and direction specified by v.  The expression F is interpreted in the coordinate system specified by c, if provided, and otherwise in the current coordinate system.

The DirectionalDiff(F,v,c) command, where F is a VectorField, computes the VectorField of directional derivatives of each component of F with respect to v.

The argument v can be a free Vector in Cartesian coordinates, a position Vector, a vector field or a rooted Vector.  If v is one of the first three, the result will be a scalar field of all directional derivatives in $R^n$ in the directions specified by v; this scalar field will be given in the same coordinate system as is used to interpret expression F.  If v is a rooted Vector, the result is the value of the directional derivative of F in the direction of v taken at the root point of v.

If F is a scalar function, the Vector v is normalized. If F is a VectorField, the Vector v is not normalized.

The DirectionalDiff(F,p,dir,c) command computes the directional derivative of F at the point p in the direction dir, where F is interpreted in the coordinate system specified by c, if provided, and otherwise in the current coordinate system.  The point p can be a list, a free Vector in Cartesian coordinates or a position Vector. The direction dir can be a free Vector in Cartesian coordinates, a position Vector or a vector field.  The result is the value of DirectionalDiff(F,dir,c) evaluated at the point p.

If c is a list of names, the directional derivative of F is taken with respect to these names in the current coordinate system.

If c is an indexed coordinate system, F is interpreted in the combination of that coordinate system and coordinate names.

If c is not specified, F is interpreted in the current coordinate system, whose coordinate name indices define the function's variables.

An operator implementing the directional derivative with respect to a VectorField can be obtained using the dot operator with Del, as in $V·\mathrm{Del}$.

with(VectorCalculus):

SetCoordinates(cartesian[x,y]);

${\mathrm{cartesian}}_{x,y}$

v1 := <1, 2>:

DirectionalDiff(r^2, v1, polar[r,t]);

$\frac{2r\cos \left(t\right)\sqrt{5}}{5}+\frac{4r\sin \left(t\right)\sqrt{5}}{5}$

W := VectorField(<u+v,v>, cartesian[u,v]);

$W≔\left(u+v\right){\stackrel{\&lowbar;}{e}}_u\&plus;\left(v\right){\stackrel{\&lowbar;}{e}}_v$

DirectionalDiff(r^2, point=[1,Pi], W, polar[r,t]);

$2$

dd := DirectionalDiff(r^2, W, polar[r,t]):

simplify( eval( dd, [r=1, t=Pi] ) );

$2$

dd := DirectionalDiff(VectorField(<x/y,x*y>), W);

$\mathrm{dd}≔\left(\frac{x+y}{y}-\frac{x}{y}\right){\stackrel{\&lowbar;}{e}}_x\&plus;\left(\left(x+y\right)y+yx\right){\stackrel{\&lowbar;}{e}}_y$

DirectionalDiff(p*q, <1,2>, [p,q]);

$\frac{q\sqrt{5}}{5}+\frac{2p\sqrt{5}}{5}$

v2 := <1, 0>:

SetCoordinates(polar);

$\mathrm{polar}$

dd := DirectionalDiff(r*cos(theta), v2, [r,theta]): # v2 is in cartesian coordinates

simplify( dd );

$1$

SetCoordinates(polar[r, t]);

${\mathrm{polar}}_{r,t}$

vs := VectorSpace([1, Pi/2], polar[r, t]):

v3 := vs:-Vector([1, 1]);

$\mathrm{v3}≔\left[\begin{array}{c}1\\ 1\end{array}\right]$

v4 := vs:-Vector([0, 1]);

$\mathrm{v4}≔\left[\begin{array}{c}0\\ 1\end{array}\right]$

DirectionalDiff(r^2, v3);

$\sqrt{2}$

DirectionalDiff(r^2, v4);

$0$

SetCoordinates(cartesian[x, y]);

${\mathrm{cartesian}}_{x,y}$

DirectionalDiff(y^2*x^2, point=[1, 2], <0, 1>, cartesian[x, y]);

$4$

DirectionalDiff(y^2*x^2, RootedVector(root=[1, 2], [0, 1]), cartesian[x, y]);

$4$

DirectionalDiff(y^2*x^2, RootedVector(root=[1, Pi/2], [1, 1], polar[r, t]), cartesian[x, y]);

$0$

SetCoordinates(cartesian[x,y,z]);

${\mathrm{cartesian}}_{x,y,z}$

V := VectorField(<y*z, x*z, x*y>);

$V≔\left(yz\right){\stackrel{\&lowbar;}{e}}_x\&plus;\left(xz\right){\stackrel{\&lowbar;}{e}}_y\&plus;\left(yx\right){\stackrel{\&lowbar;}{e}}_z$

normal( (V.Del)((x*y*z)) );

$\sqrt{y^2{x}^2+x^2{z}^2+y^2{z}^2}$

(V.Del)(VectorField(<1/x, 1/y, 1/z>));

$\left(-\frac{yz}{x^2}\right){\stackrel{\&lowbar;}{e}}_x\&plus;\left(-\frac{xz}{y^2}\right){\stackrel{\&lowbar;}{e}}_y\&plus;\left(-\frac{yx}{z^2}\right){\stackrel{\&lowbar;}{e}}_z$