restart:

if Maplets[Examples][Alert]( "Do you really want to delete the file?" ) = true then
    fremove( "whateverfile.mpl" );
end if;

restart:

cpv := Maplets[Examples][Confirm]( "Should Cauchy principal value integration be used?" ):

if cpv = true then
    int( 1/x^3, x = -3..5, CauchyPrincipalValue );
elif cpv = false then
    int( 1/x^3, x = -3..5 );
else
    NULL;
end if;

restart:

MyPlot := proc()
    plot( args, color = Maplets[Examples][GetColor]() );
end proc:

MyPlot( sin(x), x = 0..2*Pi );

restart:

MySolve := proc()
    solve( Maplets[Examples][GetEquation]( 'caption' = "Enter an equation in `x`:" ), x );
end proc:

MySolve();

restart:

MyDiffx := proc()
    diff( Maplets[Examples][GetExpression]( 'caption' = "Enter an expression in `x`:" ), x );
end proc:

MyDiffx();

restart:

# fremove( Maplets[Examples][GetFile]() );

restart:

parse( Maplets[Examples][GetInput]( "Enter an integer:", 'type' = plain ) );

restart:

Maplets[Examples][Integration]( 1/x^3 );

restart:

Maplets[Examples][KernelOpts]();

restart:

M := <<1,5>|<3,7>>;

V := <1,5,3>;

Maplets[Examples][LinearAlgebra][BezoutMatrix]();

Maplets[Examples][LinearAlgebra][ConditionNumber](M);

Maplets[Examples][LinearAlgebra][HilbertMatrix]();

Maplets[Examples][LinearAlgebra][MatrixNorm](M);

Maplets[Examples][LinearAlgebra][QRDecomposition](M);

Maplets[Examples][LinearAlgebra][SingularValues](M);

Maplets[Examples][LinearAlgebra][VectorNorm](V);

restart:

MySolve := proc()
    local solns;

    solns := solve( args );

    if solns = NULL then
        if _SolutionsMayBeLost then
            Maplets[Examples][Message]( "No solutions, but some solutions may have been lost" );
        else
            Maplets[Examples][Message]( "No solutions" );
        end if;
    else
        Maplets[Examples][Message]( sprintf( "%q", solns ) );
    end if;

    solns;
end proc:

MySolve(x^3 - 6.3 * x);

restart:

MySignum := proc(x)
    local sgnm;

    sgnm := signum( 0, x, 0 );

    if type( sgnm, 'specfunc'('anything', 'signum') ) then
        if Maplets[Examples][Question]( sprintf( "Is %a positive?", x ) ) then
            1;
        else
            sgnm;
        end if;
    else
        sgnm;
    end if;
end proc:

assume( s1 > 0 );

MySignum( s1 );

MySignum( s2 );

restart:

MyQRDecomposition := proc(M::Matrix)
    LinearAlgebra[QRDecomposition]( args, output = [seq(
            [Q, R, rank][i],
            i = [Maplets[Examples][Selection]( ["Q", "R", "rank"], default = 1 )]
    )] );
end proc:

MyQRDecomposition( <<1,2,5>|<5,3,6>|<2,5,3>> );

restart:

MyConversionTable := proc(L::list(name))
    Maplets[Examples][ShowTable](
        map2( map, convert, op(1, convert( L, conversion_table, output = columns, filter = evalf[5] )), string ),
        width = 500
    );
end proc:

MyConversionTable( [kg, g, lb, stone] );

restart:

MyInt := proc(integrand::algebraic, var::{name, name = range})
    local indts, i, positives, varT;

    if type( var, name ) then
        varT := var;
    else
        varT := lhs( var );
    end if;

    indts := select( 'type', indets( integrand ), 'name' ) minus {varT};

    positives := NULL;

    for i in indts do
        if Maplets[Examples][SignQuery]( i ) then
            positives := positives, i::positive;
        end if;
    end do;

    int( integrand, var ) assuming positives;
end proc:

MyInt( exp(-n*x), x=0..infinity );