restart:

with(Maplets[Elements]):

V := <1, 3, 5, 7-I>;

# Define the Maplet application.
maplet := Maplet(BoxLayout('vertical'=true,

    # A paragraph describing the vector norm.
    TextBox( "A vector norm is a function ||V|| that satisfies "
             "the conditions of a norm.",
             'height' = 2, 'width' = 40, 'editable' = 'false' ),

    # Three rows, each requesting the user for various
    # forms of input. The first check box has a default
    # value determined by the return value of a Maple call.
    # The second check box is selected by default.

    BoxRow(
       BoxCell( "Norm (Select or enter a non-negative number):",
                'halign'='left' ),
       BoxCell( ComboBox['CoB1'](["infinity", "1", "Euclidean (2)",
                "Frobenius"]), 'halign'='right' )
    ),
    BoxRow(
       BoxCell( "The vector has real entries:", 'halign'='left' ),
       BoxCell( CheckBox['ChB1'](not has(V, I)), 'halign'='right' )
    ),
    BoxRow(
       BoxCell( "Evaluate result:", 'halign'='left' ),
       BoxCell( CheckBox['ChB2'](true), 'halign'='right' )
    ),

    BoxRow(
       # The OK button shuts down the Maplet application and
       # returns the results in the combo and check boxes
       BoxCell( Button("OK", Shutdown(['CoB1', 'ChB1', 'ChB2'])),
               'halign'='left' ),

       # The Cancel button shuts down the Maplet application
       # without returning any results.
       BoxCell( Button("Cancel", Shutdown()), 'halign'='right' )
    )
)):

# Display runs the Maplet application.
continue := false;
result := Maplets[Display](maplet);

if type( result, list ) then
    n := subs( ["infinity" = infinity, "1" = 1, "Euclidean (2)" = 2, "Frobenius" = Frobenius], result[1] );

    if type( n, 'string' ) then
        try
            n := parse( n );
        catch:
            n := Maplets[Examples][GetInput]( "The following, expected to be of type `nonnegative`, does not parse:",
                'value' = n );

            if type( n, 'string' ) then
                try
                    n := parse( n );
                catch:
                    continue := false;
                    error "the expression `%1` does not parse", n;
                end try;
            end if;
        end try;

        if not type( n, 'nonnegative' ) then
            continue := false;
            error "the expression `%1` is not of type `%2`", n, nonnegative;
        end if;
    end if;

    c := not parse( result[2] );
    er := parse( result[3] );
    continue := true;
else
    continue := false;
end if:

if continue then
    if er then
        answer := LinearAlgebra[VectorNorm]( V, n, conjugate = c );
    else
        answer := ''LinearAlgebra[VectorNorm]''( V, n, conjugate = c );
    end if;
end if:

answer;

?Maplets,Examples,VectorNorm

print( Maplets[Examples][LinearAlgebra][VectorNorm] );