create a new American-style swaption
AmericanSwaption(irswap, earliestexercise, latestexercise, opts)
simple swap data structures; interest rate swap
a non-negative constant, a string containing a date specification in a format recognized by ParseDate, or a date data structure; the earliest date or time when the option can be exercised
a non-negative constant, a string containing a date specification in a format recognized by ParseDate, or a date data structure; the maturity time or date
(optional) equation(s) of the form option = value where option is one of referencedate or daycounter; specify options for the AmericanSwaption command
referencedate = a string containing a date specification in a format recognized by ParseDate or a date data structure -- This option provides the evaluation date. It is set to the global evaluation date by default.
daycounter = a name representing a supported day counter (e.g. ISDA, Simple) or a day counter data structure created using the DayCounter constructor -- This option provides a day counter that will be used to convert the period between two dates to a fraction of the year. This option is used only if one of earliestexercise or latestexercise is specified as a date.
The AmericanSwaption command creates a new American-style swaption with the specified payoff and maturity. The swaption can be exercised at any time between earliestexercise and latestexercise dates. This is the opposite of a European-style swaption, which can only be exercised on the date of expiration.
The parameter irswap is the underlying interest rate swap (see InterestRateSwap for more details).
The parameter earliestexercise specifies the earliest time or date when the option can be exercised. It can be given either as a non-negative constant or as a date in any of the formats recognized by the ParseDate command. If earlyexercise is given as a date, then the period between referencedate and earliestexercise will be converted to a fraction of the year according to the day count convention specified by daycounter. Typically the value of this option is 0, which means that the option can be exercised at any time until the maturity. Note that the time of the earliest exercise must precede the maturity time.
The parameter latestexercise specifies the maturity time of the option. It can be given either as a non-negative constant or as a date in any of the formats recognized by the ParseDate command. If earlyexercise is given as a date, then the period between referencedate and latestexercise will be converted to a fraction of the year according to the day count convention specified by daycounter.
The LatticePrice command can be used to price an American-style swaption using any given binomial or trinomial tree.
SetEvaluationDate("November 17, 2006"):
November 17, 2006
nominal := 1000.0;
fixing_days := 2;
start := AdvanceDate(1, Years, EURIBOR);
start≔November 17, 2007
maturity := AdvanceDate(start, 5, Years, EURIBOR);
maturity≔November 17, 2012
discount_curve := ForwardCurve(0.04875825, 'daycounter' = Actual365Fixed);
fixed_schedule := Schedule(start, maturity, Annual, 'convention' = Unadjusted, 'calendar' = EURIBOR);
floating_schedule := Schedule(start, maturity, Semiannual, 'convention' = ModifiedFollowing, 'calendar' = EURIBOR);
benchmark := BenchmarkRate(6, Months, EURIBOR, 0.04875825);
Construct an interest rate swap receiving the fixed-rate payments in exchange for the floating-rate payment.
swap := InterestRateSwap(nominal, 0.0, fixed_schedule, benchmark, floating_schedule, 0.0);
Compute the at-the-money rate for this interest rate swap.
atm_rate := FairRate(swap, discount_curve);
Construct three swaps.
itm_swap := InterestRateSwap(nominal, 0.8*atm_rate, fixed_schedule, benchmark, floating_schedule, 0.0);
atm_swap := InterestRateSwap(nominal, 1.0*atm_rate, fixed_schedule, benchmark, floating_schedule, 0.0);
otm_swap := InterestRateSwap(nominal, 1.2*atm_rate, fixed_schedule, benchmark, floating_schedule, 0.0);
Here are cash flows for the paying leg of your interest rate swap.
cash_flows := CashFlows(itm_swap, paying);
cash_flows≔39.97833882 on 'November 17, 2008',39.95141436 on 'November 17, 2009',39.96487659 on 'November 17, 2010',39.96487659 on 'November 17, 2011',39.97833882 on 'November 19, 2012'
Here are cash flows for the receiving leg of your interest rate swap.
24.55793340 on 'May 19, 2008',24.54222773 on 'November 17, 2008',24.59383300 on 'May 18, 2009',24.74716833 on 'November 17, 2009',24.47342475 on 'May 17, 2010',24.88406756 on 'November 17, 2010',24.47342475 on 'May 17, 2011',24.88406756 on 'November 17, 2011',24.55868130 on 'May 17, 2012',25.08832826 on 'November 19, 2012'
These are days when coupon payments are scheduled to occur.
dates := map(t -> t[date], cash_flows);
itm_swaption := AmericanSwaption(itm_swap, AdvanceDate(start, 1, Days, EURIBOR), AdvanceDate(dates[-2], 1, Days, EURIBOR));
atm_swaption := AmericanSwaption(atm_swap, AdvanceDate(start, 1, Days, EURIBOR), AdvanceDate(dates[-2], 1, Days, EURIBOR));
otm_swaption := AmericanSwaption(otm_swap, AdvanceDate(start, 1, Days, EURIBOR), AdvanceDate(dates[-2], 1, Days, EURIBOR));
Price these swaptions using the Hull-White trinomial tree.
a := 0.048696;
sigma := 0.0058904;
model := HullWhiteModel(discount_curve, a, sigma);
time_grid := TimeGrid(YearFraction(maturity)+.5, 100);
short_rate_tree := ShortRateTree(model, time_grid);
Price the swaptions using the tree constructed above.
LatticePrice(itm_swaption, short_rate_tree, discount_curve);
LatticePrice(atm_swaption, short_rate_tree, discount_curve);
LatticePrice(otm_swaption, short_rate_tree, discount_curve);
You can also price these swaptions using an explicitly constructed trinomial tree.
ou_process := OrnsteinUhlenbeckProcess(0.04875, 0.04875, 1.0, 0.3);
tree := ShortRateTree(ou_process, time_grid);
Price your swaptions using the second tree.
LatticePrice(itm_swaption, tree, discount_curve);
LatticePrice(atm_swaption, tree, discount_curve);
LatticePrice(otm_swaption, tree, discount_curve);
Brigo, D., Mercurio, F., Interest Rate Models: Theory and Practice. New York: Springer-Verlag, 2001.
Hull, J., Options, Futures, and Other Derivatives, 5th. edition. Upper Saddle River, New Jersey: Prentice Hall, 2003.
The Finance[AmericanSwaption] command was introduced in Maple 15.
For more information on Maple 15 changes, see Updates in Maple 15.
Download Help Document
What kind of issue would you like to report? (Optional)