Finance - Maple Programming Help

Home : Support : Online Help : Mathematics : Finance : Stochastic Processes : Finance/PoissonProcess

Finance

 PoissonProcess
 create new Poisson process

 Calling Sequence PoissonProcess(lambda) PoissonProcess(lambda, X)

Parameters

 lambda - algebraic expression; intensity parameter X - algebraic expression; jump size distribution

Description

 • A Poisson process with intensity parameter $0<\mathrm{\lambda }\left(t\right)$, where $\mathrm{\lambda }\left(t\right)$ is a deterministic function of time, is a stochastic process $N$ with independent increments such that $N\left(0\right)=0$ and

$\mathrm{Pr}\left(N\left(t+h\right)-N\left(t\right)=1\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}|\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}N\left(t\right)\right)=\mathrm{lambda}\left(t\right)h+o\left(h\right)$

 for all $0\le t$. If the intensity parameter $\mathrm{\lambda }\left(t\right)$ itself is stochastic, the corresponding process is called a doubly stochastic Poisson process or Cox process.
 • A compound Poisson process is a stochastic process $J\left(t\right)$ of the form $J\left(t\right)={\sum }_{i=1}^{N\left(t\right)}{Y}_{i}$, where $N\left(t\right)$ is a standard Poisson process and ${Y}_{i}$ are independent and identically distributed random variables. A compound Cox process is defined in a similar way.
 • The parameter lambda is the intensity. It can be constant or time-dependent. It can also be a function of other stochastic variables, in which case the so-called doubly stochastic Poisson process (or Cox process) will be created.
 • The parameter X is the jump size distribution. The value of X can be a distribution, a random variable or any algebraic expression involving random variables.
 • If called with one parameter, the PoissonProcess command creates a standard Poisson or Cox process with the specified intensity parameter.

Examples

 > with(Finance):
 > J := PoissonProcess(1.0):
 > PathPlot(J(t), t = 0..3, timesteps = 50, replications = 20, thickness = 3, color = red..blue, axes = BOXED, gridlines = true, markers = false);

Create a subordinated Wiener process with $J$ as a subordinator.

 > W := WienerProcess(J):
 > PathPlot(W(t), t = 0..3, timesteps = 20, replications = 10, markers = false, color = red..blue, thickness = 3, gridlines = true, axes = BOXED);

Next define a compound Poisson process.

 > Y := Statistics[RandomVariable](Normal(.3, .5)):
 > lambda := 0.5;
 ${\mathrm{\lambda }}{≔}{0.5}$ (1)
 > X := PoissonProcess(lambda, Y):
 > PathPlot(X(t), t = 0..3, timesteps = 20, replications = 10, markers = false, color = red..blue, thickness = 3, gridlines = true, axes = BOXED);

Compute the expected value of $X\left(T\right)$ for $T=3$ and verify that this is approximately equal to $\mathrm{\lambda }T$ times the expected value of $Y$.

 > T := 3;
 ${T}{≔}{3}$ (2)
 > ExpectedValue(X(T), replications = 10^4, timesteps = 100);
 $\left[{\mathrm{value}}{=}{0.4435146732}{,}{\mathrm{standarderror}}{=}{0.007164725012}\right]$ (3)
 > lambda*T*Statistics[ExpectedValue](Y);
 ${0.45}$ (4)

Here is an example of a doubly stochastic Poisson process for which the intensity parameter evolves as a square-root diffusion.

 > kappa := 0.354201;
 ${\mathrm{\kappa }}{≔}{0.354201}$ (5)
 > mu    := 1.21853;
 ${\mathrm{\mu }}{≔}{1.21853}$ (6)
 > nu    := 0.538186;
 ${\mathrm{\nu }}{≔}{0.538186}$ (7)
 > y0    := 1.81;
 ${\mathrm{y0}}{≔}{1.81}$ (8)
 > y := SquareRootDiffusion(y0, kappa, mu, nu):
 > J := PoissonProcess(y(t)):
 > PathPlot(y(t), t = 0..3, timesteps = 100, replications = 10, thickness = 3, color = red..blue, axes = BOXED, gridlines = true);
 > PathPlot(J(t), t = 0..3, timesteps = 100, replications = 10, thickness = 3, color = red..blue, axes = BOXED, gridlines = true);

References

 Glasserman, P., Monte Carlo Methods in Financial Engineering. New York: Springer-Verlag, 2004.

Compatibility

 • The Finance[PoissonProcess] command was introduced in Maple 15.