Lesson 8: Pullbacks of DifferentialForms - Maple Help
For the best experience, we recommend viewing online help using Google Chrome or Microsoft Edge.

Online Help

All Products    Maple    MapleSim

DifferentialGeometry Lessons

Lesson 8: The Pullback of a Differential Form by a Transformation

Overview

In this lesson, you will learn to do the following:

 – Pullback a differential form.
 – Determine if a submanifold is a integral manifold to an exterior differential system.
 – Integrate a differential form.
 – Check the invariance of a function, vector field, differential form, or tensor.
 – Apply the "cylinder construction" option for the DeRhamHomotopy command.

Pullback

The basic properties of the pullback are listed in Exercise 5.  Here we illustrate the fact that the pointwise pullback of a differential 1-form can be computed directly from the Jacobian matrix J of the transformation by simply multiplying the components of the 1-form (as a row vector) by J.

 > with(DifferentialGeometry):
 > DGsetup([x, y, z], M):
 M > DGsetup([u, v], N):

Define a transformation psi, a 1-form alpha and a point p.

 N > psi := Transformation(M, N,[u = (x^2 + y^2), v = z^2 - y^2]);
 ${\mathrm{ψ}}{≔}\left[{u}{=}{{x}}^{{2}}{+}{{y}}^{{2}}{,}{v}{=}{{z}}^{{2}}{-}{{y}}^{{2}}\right]$ (2.1)
 M > alpha := evalDG(1/2*v*du - 1/2*u*dv);
 ${\mathrm{α}}{≔}\frac{{v}{}{\mathrm{du}}}{{2}}{-}\frac{{u}{}{\mathrm{dv}}}{{2}}$ (2.2)
 N > p := [x = 2, y = 3, z = 4];
 ${p}{≔}\left[{x}{=}{2}{,}{y}{=}{3}{,}{z}{=}{4}\right]$ (2.3)

We pull alpha back using psi and evaluate the result at p.

 N > theta := Pullback(psi, alpha);
 ${\mathrm{θ}}{≔}{-}\left({-}{{z}}^{{2}}{+}{{y}}^{{2}}\right){}{x}{}{\mathrm{dx}}{+}\left({y}{}{{x}}^{{2}}{+}{y}{}{{z}}^{{2}}\right){}{\mathrm{dy}}{-}\left({{x}}^{{2}}{+}{{y}}^{{2}}\right){}{z}{}{\mathrm{dz}}$ (2.4)
 M > theta1 := eval(theta, p);
 ${\mathrm{θ1}}{≔}{14}{}{\mathrm{dx}}{+}{60}{}{\mathrm{dy}}{-}{52}{}{\mathrm{dz}}$ (2.5)

Let's recalculate the pullback of the form alpha using the Jacobian of psi.  First, we need the image of p under psi.

 M > q := ApplyTransformation(psi, p);
 ${q}{≔}\left[{u}{=}{13}{,}{v}{=}{7}\right]$ (2.6)

Evaluate alpha at q.

 N > alpha1 := eval(alpha, q);
 ${\mathrm{α1}}{≔}\frac{{7}{}{\mathrm{du}}}{{2}}{-}\frac{{13}{}{\mathrm{dv}}}{{2}}$ (2.7)

Use DGinfo to get the coefficients of alpha1 and the Jacobian J of phi.

 N > A := Tools:-DGinfo(alpha1, "CoefficientList", "all");
 ${A}{≔}\left[\frac{{7}}{{2}}{,}{-}\frac{{13}}{{2}}\right]$ (2.8)
 N > J := eval(Tools:-DGinfo(psi, "JacobianMatrix"), p);
 ${J}{≔}\left[\begin{array}{rrr}{4}& {6}& {0}\\ {0}& {-}{6}& {8}\end{array}\right]$ (2.9)

Calculate the coefficients of the pullback of alpha1 by phi using matrix multiplication.

 N > B := LinearAlgebra:-Transpose(Vector(A)).J;
 ${B}{≔}\left[\begin{array}{ccc}{14}& {60}& {-}{52}\end{array}\right]$ (2.10)
 N > theta2 := DGzip(B, [dx, dy, dz], "plus");
 ${\mathrm{θ2}}{≔}{14}{}{\mathrm{dx}}{+}{60}{}{\mathrm{dy}}{-}{52}{}{\mathrm{dz}}$ (2.11)

Application 1: Integral Manifolds of Exterior Differential Systems

 M > restart;with(DifferentialGeometry):

Let Omega be an exterior differential system (EDS) on a manifold M.  An integral manifold of Omega is an immersion sigma : N -> M such that sigma^*(omega) = 0 for all differential p-forms omega in Omega.  If Omega is generated, as a differential ideal, by forms omega[1], omega[2], ... omega[N], then sigma is an integral manifold if and only if the pullback sigma^*(omega[i]) = 0 for i = 1 ... N.  The forms omega[i] need not be 1-forms.

In each of the following examples, we check that the map sigma is an integral manifold for the given EDS Omega.

Example 1.  This EDS is the canonical contact system on the jet space J^3(R, R).

 > DGsetup([x], N1): DGsetup([x, y, y1, y2, y3], M1):
 M1 > Omega := evalDG([dy - y1*dx, dy1 - y2*dx, dy2 - y3*dx]);
 ${\mathrm{Ω}}{≔}\left[{-}{\mathrm{y1}}{}{\mathrm{dx}}{+}{\mathrm{dy}}{,}{-}{\mathrm{y2}}{}{\mathrm{dx}}{+}{\mathrm{dy1}}{,}{-}{\mathrm{y3}}{}{\mathrm{dx}}{+}{\mathrm{dy2}}\right]$ (3.1)
 M1 > sigma := Transformation(N1, M1, [x = x, y = f(x), y1 = diff(f(x), x), y2 = diff(f(x), x$2), y3 = diff(f(x), x$3)]);
 ${\mathrm{σ}}{≔}\left[{x}{=}{x}{,}{y}{=}{f}{}\left({x}\right){,}{\mathrm{y1}}{=}\frac{{ⅆ}}{{ⅆ}{x}}{}{f}{}\left({x}\right){,}{\mathrm{y2}}{=}\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{x}}^{{2}}}{}{f}{}\left({x}\right){,}{\mathrm{y3}}{=}\frac{{{ⅆ}}^{{3}}}{{ⅆ}{{x}}^{{3}}}{}{f}{}\left({x}\right)\right]$ (3.2)
 N1 > Pullback(sigma, Omega);
 $\left[{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}\right]$ (3.3)

Example 2.  This EDS is the canonical contact system on the jet space J^1(R^2, R).

 N1 > DGsetup([x, y], N2):
 N2 > DGsetup([x, y, u, p, q, r, s, t], M2):
 M2 > Omega := evalDG([du - p*dx - q*dy, dp - r*dx - s*dy, dq - s*dx - t*dy]);
 ${\mathrm{Ω}}{≔}\left[{-}{p}{}{\mathrm{dx}}{-}{q}{}{\mathrm{dy}}{+}{\mathrm{du}}{,}{-}{r}{}{\mathrm{dx}}{-}{s}{}{\mathrm{dy}}{+}{\mathrm{dp}}{,}{-}{s}{}{\mathrm{dx}}{-}{t}{}{\mathrm{dy}}{+}{\mathrm{dq}}\right]$ (3.4)
 M2 > sigma := Transformation(N2, M2, [x = x, y = y, u = f(x, y), p = diff(f(x, y), x), q = diff(f(x, y), y), r = diff(f(x, y), x$2), s = diff(f(x, y), x, y), t = diff(f(x, y), y$2)]);
 ${\mathrm{σ}}{≔}\left[{x}{=}{x}{,}{y}{=}{y}{,}{u}{=}{f}{}\left({x}{,}{y}\right){,}{p}{=}\frac{{\partial }}{{\partial }{x}}{}{f}{}\left({x}{,}{y}\right){,}{q}{=}\frac{{\partial }}{{\partial }{y}}{}{f}{}\left({x}{,}{y}\right){,}{r}{=}\frac{{{\partial }}^{{2}}}{{\partial }{{x}}^{{2}}}{}{f}{}\left({x}{,}{y}\right){,}{s}{=}\frac{{{\partial }}^{{2}}}{{\partial }{y}{}{\partial }{x}}{}{f}{}\left({x}{,}{y}\right){,}{t}{=}\frac{{{\partial }}^{{2}}}{{\partial }{{y}}^{{2}}}{}{f}{}\left({x}{,}{y}\right)\right]$ (3.5)
 N2 > Pullback(sigma, Omega);
 $\left[{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}\right]$ (3.6)

Example 3.  Find the integral 1-manifolds to the EDS Omega of the form [x = x, y = f(x), y1 = g(x), y2 = h(x), y3 = k(x)].

 N2 > ChangeFrame(M1):
 M1 > Omega := evalDG([dy - y1*dx, dy1 - y2*dx, dy2 - y3*dx, dy3 - y*dx]);
 ${\mathrm{Ω}}{≔}\left[{-}{\mathrm{y1}}{}{\mathrm{dx}}{+}{\mathrm{dy}}{,}{-}{\mathrm{y2}}{}{\mathrm{dx}}{+}{\mathrm{dy1}}{,}{-}{\mathrm{y3}}{}{\mathrm{dx}}{+}{\mathrm{dy2}}{,}{-}{y}{}{\mathrm{dx}}{+}{\mathrm{dy3}}\right]$ (3.7)
 M1 > sigma := Transformation(N1, M1, [x = x, y = f(x), y1 = g(x), y2 = h(x), y3 = k(x)]);
 ${\mathrm{σ}}{≔}\left[{x}{=}{x}{,}{y}{=}{f}{}\left({x}\right){,}{\mathrm{y1}}{=}{g}{}\left({x}\right){,}{\mathrm{y2}}{=}{h}{}\left({x}\right){,}{\mathrm{y3}}{=}{k}{}\left({x}\right)\right]$ (3.8)

Pullback the forms in the list Omega using sigma.  Extract the coefficients of the resulting forms to obtain a system of 1st order ODEs.

 N1 > Theta := Pullback(sigma, Omega);
 ${\mathrm{Θ}}{≔}\left[\left(\frac{{ⅆ}}{{ⅆ}{x}}{}{f}{}\left({x}\right){-}{g}{}\left({x}\right)\right){}{\mathrm{dx}}{,}\left(\frac{{ⅆ}}{{ⅆ}{x}}{}{g}{}\left({x}\right){-}{h}{}\left({x}\right)\right){}{\mathrm{dx}}{,}\left(\frac{{ⅆ}}{{ⅆ}{x}}{}{h}{}\left({x}\right){-}{k}{}\left({x}\right)\right){}{\mathrm{dx}}{,}\left(\frac{{ⅆ}}{{ⅆ}{x}}{}{k}{}\left({x}\right){-}{f}{}\left({x}\right)\right){}{\mathrm{dx}}\right]$ (3.9)
 N1 > DE := map(op, map(Tools:-DGinfo, Theta, "CoefficientSet"));
 ${\mathrm{DE}}{≔}\left[\frac{{ⅆ}}{{ⅆ}{x}}{}{f}{}\left({x}\right){-}{g}{}\left({x}\right){,}\frac{{ⅆ}}{{ⅆ}{x}}{}{g}{}\left({x}\right){-}{h}{}\left({x}\right){,}\frac{{ⅆ}}{{ⅆ}{x}}{}{h}{}\left({x}\right){-}{k}{}\left({x}\right){,}\frac{{ⅆ}}{{ⅆ}{x}}{}{k}{}\left({x}\right){-}{f}{}\left({x}\right)\right]$ (3.10)

Use dsolve to solve these ODEs.

 N1 > Soln := dsolve(DE);
 ${\mathrm{Soln}}{≔}\left\{{k}{}\left({x}\right){=}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{+}{\mathrm{_C3}}{}{\mathrm{sin}}{}\left({x}\right){+}{\mathrm{_C4}}{}{\mathrm{cos}}{}\left({x}\right){,}{h}{}\left({x}\right){=}{-}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{-}{\mathrm{_C3}}{}{\mathrm{cos}}{}\left({x}\right){+}{\mathrm{_C4}}{}{\mathrm{sin}}{}\left({x}\right){,}{g}{}\left({x}\right){=}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{-}{\mathrm{_C3}}{}{\mathrm{sin}}{}\left({x}\right){-}{\mathrm{_C4}}{}{\mathrm{cos}}{}\left({x}\right){,}{f}{}\left({x}\right){=}{-}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{+}{\mathrm{_C3}}{}{\mathrm{cos}}{}\left({x}\right){-}{\mathrm{_C4}}{}{\mathrm{sin}}{}\left({x}\right)\right\}$ (3.11)

Substitute back into the original transformation sigma.

 N1 > Sigma := eval(sigma, Soln);
 ${\mathrm{Σ}}{≔}\left[{x}{=}{x}{,}{y}{=}{-}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{+}{\mathrm{_C3}}{}{\mathrm{cos}}{}\left({x}\right){-}{\mathrm{_C4}}{}{\mathrm{sin}}{}\left({x}\right){,}{\mathrm{y1}}{=}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{-}{\mathrm{_C3}}{}{\mathrm{sin}}{}\left({x}\right){-}{\mathrm{_C4}}{}{\mathrm{cos}}{}\left({x}\right){,}{\mathrm{y2}}{=}{-}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{-}{\mathrm{_C3}}{}{\mathrm{cos}}{}\left({x}\right){+}{\mathrm{_C4}}{}{\mathrm{sin}}{}\left({x}\right){,}{\mathrm{y3}}{=}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{+}{\mathrm{_C3}}{}{\mathrm{sin}}{}\left({x}\right){+}{\mathrm{_C4}}{}{\mathrm{cos}}{}\left({x}\right)\right]$ (3.12)

Check that Sigma annihilates all the forms in the EDS Omega.

 N1 > Pullback(Sigma, Omega);
 $\left[{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}\right]$ (3.13)

Example 4.  Find the integral 2-manifolds to the EDS Omega of the form [x = x, y = y, u = f(x, y), p = g(x, y), q = h(x, y)].

 N1 > DGsetup([x, y], N2):
 N2 > DGsetup([x, y, u, ux, uy], M2):
 M2 > Omega := evalDG([du - ux*dx - uy*dy, dux &w dx, duy &w dy]);
 ${\mathrm{Ω}}{≔}\left[{-}{\mathrm{ux}}{}{\mathrm{dx}}{-}{\mathrm{uy}}{}{\mathrm{dy}}{+}{\mathrm{du}}{,}{-}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dux}}{,}{-}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{duy}}\right]$ (3.14)
 M2 > sigma := Transformation(N2, M2, [x = x, y = y, u = f(x, y), ux = g(x, y), uy = h(x, y)]);
 ${\mathrm{σ}}{≔}\left[{x}{=}{x}{,}{y}{=}{y}{,}{u}{=}{f}{}\left({x}{,}{y}\right){,}{\mathrm{ux}}{=}{g}{}\left({x}{,}{y}\right){,}{\mathrm{uy}}{=}{h}{}\left({x}{,}{y}\right)\right]$ (3.15)

Pullback the forms in the list Omega using sigma.  Extract the coefficients of the resulting forms to obtain a system of 1st order PDEs.

 N2 > Theta := Pullback(sigma, Omega);
 ${\mathrm{Θ}}{≔}\left[\left(\frac{{\partial }}{{\partial }{x}}{}{f}{}\left({x}{,}{y}\right){-}{g}{}\left({x}{,}{y}\right)\right){}{\mathrm{dx}}{+}\left(\frac{{\partial }}{{\partial }{y}}{}{f}{}\left({x}{,}{y}\right){-}{h}{}\left({x}{,}{y}\right)\right){}{\mathrm{dy}}{,}{-}\left(\frac{{\partial }}{{\partial }{y}}{}{g}{}\left({x}{,}{y}\right)\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{,}\left(\frac{{\partial }}{{\partial }{x}}{}{h}{}\left({x}{,}{y}\right)\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}\right]$ (3.16)
 N2 > DE := map(op, map(Tools:-DGinfo, Theta, "CoefficientSet"));
 ${\mathrm{DE}}{≔}\left[\frac{{\partial }}{{\partial }{x}}{}{f}{}\left({x}{,}{y}\right){-}{g}{}\left({x}{,}{y}\right){,}\frac{{\partial }}{{\partial }{y}}{}{f}{}\left({x}{,}{y}\right){-}{h}{}\left({x}{,}{y}\right){,}{-}\left(\frac{{\partial }}{{\partial }{y}}{}{g}{}\left({x}{,}{y}\right)\right){,}\frac{{\partial }}{{\partial }{x}}{}{h}{}\left({x}{,}{y}\right)\right]$ (3.17)

Use pdsolve to integrate this system of PDEs.

 N2 > Soln := pdsolve(DE);
 ${\mathrm{Soln}}{≔}\left\{{f}{}\left({x}{,}{y}\right){=}{∫}{\mathrm{_F2}}{}\left({y}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{y}{+}{∫}{\mathrm{_F1}}{}\left({x}\right)\phantom{\rule[-0.0ex]{0.3em}{0.0ex}}{ⅆ}{x}{+}{\mathrm{_C1}}{,}{h}{}\left({x}{,}{y}\right){=}{\mathrm{_F2}}{}\left({y}\right){,}{g}{}\left({x}{,}{y}\right){=}{\mathrm{_F1}}{}\left({x}\right)\right\}$ (3.18)

Integration

The command IntegrateForm provides a simple means for integrating differential forms.  Here are a few examples.

[i]  Line Integrals.  Compute the line integral of the 1-form omega1 along the curve C from t = 0 to t = 2*Pi.

 N2 > with(DifferentialGeometry):
 N2 > DGsetup([t], R1):
 R1 > DGsetup([x, y, z], R3):

Define the 1-form omega1.

 R3 > omega1 := evalDG(x^2*dx - z^2*dy + y^2*dz);
 ${\mathrm{ω1}}{≔}{{x}}^{{2}}{}{\mathrm{dx}}{-}{{z}}^{{2}}{}{\mathrm{dy}}{+}{{y}}^{{2}}{}{\mathrm{dz}}$ (4.1)

Define the curve C in R3 as a transformation from R1 to R3.

 R3 > C := Transformation(R1, R3, [ x = sin(t), y = t  ,z = cos(t)]);
 ${C}{≔}\left[{x}{=}{\mathrm{sin}}{}\left({t}\right){,}{y}{=}{t}{,}{z}{=}{\mathrm{cos}}{}\left({t}\right)\right]$ (4.2)

Pull the 1-form back using the curve C and integrate the resulting form on R1 from t = 0 to t = 2*Pi.

 R1 > eta1 := Pullback(C, omega1);
 ${\mathrm{η1}}{≔}\left({-}{{t}}^{{2}}{}{\mathrm{sin}}{}\left({t}\right){-}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}{+}{\mathrm{cos}}{}\left({t}\right){-}{{\mathrm{cos}}{}\left({t}\right)}^{{3}}\right){}{\mathrm{dt}}$ (4.3)
 R1 > IntegrateForm(eta1, t = 0.. 2*Pi);
 ${4}{}{{\mathrm{π}}}^{{2}}{-}{\mathrm{π}}$ (4.4)

[ii]  Surface Integrals.  Compute the surface integral of the 2-form omega2 over the surface z = x^2 + y^2, where 1 < x^2 + y^2 <= 4.

 R1 > omega2 := evalDG(x^2*z*dx &w dy - z^3*dx &w dz);
 ${\mathrm{ω2}}{≔}{{x}}^{{2}}{}{z}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{-}{{z}}^{{3}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (4.5)

We use polar coordinates to parameterize the surface.  (theta was previously defined, so we need to unassign it here.)

 R3 > theta := 'theta';
 ${\mathrm{θ}}{≔}{\mathrm{θ}}$ (4.6)
 R3 > DGsetup([r, theta], R2):
 R2 > S := Transformation(R2, R3, [x = r*cos(theta), y = r*sin(theta), z = r^2]);
 ${S}{≔}\left[{x}{=}{r}{}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){,}{y}{=}{r}{}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){,}{z}{=}{{r}}^{{2}}\right]$ (4.7)
 R2 > eta2 := Pullback(S, omega2);
 ${\mathrm{η2}}{≔}{-}{{r}}^{{5}}{}\left({2}{}{{r}}^{{3}}{}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){-}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{2}}\right){}{\mathrm{dr}}{}{\mathrm{^}}{}{\mathrm{dtheta}}$ (4.8)
 R2 > IntegrateForm(eta2, r = 1 .. 2, theta = 0 .. 2*Pi);
 $\frac{{21}{}{\mathrm{π}}}{{2}}$ (4.9)

[iii]  Volume Integral.  Compute the integral of the 3-form omega3 over the region x + y + z + w = 1, x, y, z, w > =0.

 R2 > DGsetup([x, y, z, w], R4):
 R4 > DGsetup([r, s, t], N):
 N > omega3 := (x*y)/(1 + z)*evalDG(dx &w dy &w dz - dy &w dz &w dw);
 ${\mathrm{ω3}}{≔}\frac{{x}{}{y}{}\left({\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{-}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}\right)}{{1}{+}{z}}$ (4.10)

The transformation phi parameterizes the region of integration.

 R4 > phi := Transformation(N, R4, [x = r, y = s, z = t, w = 1 - r - s - t]);
 ${\mathrm{φ}}{≔}\left[{x}{=}{r}{,}{y}{=}{s}{,}{z}{=}{t}{,}{w}{=}{1}{-}{r}{-}{s}{-}{t}\right]$ (4.11)

Pullback omega3 by phi and integrate the result.

 N > eta3 := Pullback(phi, omega3);
 ${\mathrm{η3}}{≔}\frac{{2}{}{r}{}{s}{}{\mathrm{dr}}{}{\mathrm{^}}{}{\mathrm{ds}}{}{\mathrm{^}}{}{\mathrm{dt}}}{{1}{+}{t}}$ (4.12)
 N > IntegrateForm(eta3, r = 0 .. 1, s = 0 .. r, t = 0 .. r + s);
 $\frac{{25}}{{48}}{-}\frac{{9}}{{8}}{}{\mathrm{ln}}{}\left({3}\right){+}\frac{{4}}{{3}}{}{\mathrm{ln}}{}\left({2}\right)$ (4.13)

Stokes Theorem

Let M be an n-dimensional manifold with boundary N and let omega be an (n-1)-form.  Stokes Theorem states that

int_N omega = int_M (d(omega))   (*)

Let us check this formula, where M is the (solid) ball of radius 1 centered at the origin, N is the unit 2-sphere and omega is the 2-form defined below.  We shall use spherical coordinates to evaluate the integrals.

 N > restart: with(DifferentialGeometry):
 > DGsetup([x, y, z], R3):
 R3 > DGsetup([rho, theta, phi], B3):
 B3 > DGsetup([theta, phi], S2):
 S2 > omega := evalDG(-(x^2 + y^2)*z*dx &w dy - (y^2 + z^2)*x*dx &w dz + x^2*y^2*z^2*dy &w dz);
 ${\mathrm{ω}}{≔}{-}\left({{x}}^{{2}}{+}{{y}}^{{2}}\right){}{z}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{-}\left({{y}}^{{2}}{+}{{z}}^{{2}}\right){}{x}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}{{x}}^{{2}}{}{{y}}^{{2}}{}{{z}}^{{2}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (5.1)

The transformation F parameterizes the boundary N of the ball.

 R3 > F := Transformation(S2, R3, [x = cos(theta)*sin(phi), y = sin(theta)*sin(phi), z = cos(phi)]);
 ${F}{≔}\left[{x}{=}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){,}{y}{=}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){,}{z}{=}{\mathrm{cos}}{}\left({\mathrm{φ}}\right)\right]$ (5.2)

The transformation G will be used to integrate omega over the ball M.

 S2 > G := Transformation(B3, R3, [x = rho*cos(theta)*sin(phi), y = rho*sin(theta)*sin(phi), z = rho*cos(phi)]);
 ${G}{≔}\left[{x}{=}{\mathrm{ρ}}{}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){,}{y}{=}{\mathrm{ρ}}{}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){,}{z}{=}{\mathrm{ρ}}{}{\mathrm{cos}}{}\left({\mathrm{φ}}\right)\right]$ (5.3)
 B3 > omega1 := Pullback(F, omega);
 ${\mathrm{ω1}}{≔}{-}{{\mathrm{sin}}{}\left({\mathrm{φ}}\right)}^{{3}}{}\left({{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{3}}{}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{-}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{3}}{}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{4}}{-}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{5}}{}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{+}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{5}}{}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{4}}{+}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){-}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{3}}{}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){+}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{3}}{}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{-}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}\right){}{\mathrm{dtheta}}{}{\mathrm{^}}{}{\mathrm{dphi}}$ (5.4)

Calculate the left hand side of Stokes' formula.

 S2 > StokesLHS := IntegrateForm(omega1, theta = 0 .. 2*Pi, phi = 0..Pi);
 ${\mathrm{StokesLHS}}{≔}\frac{{8}{}{\mathrm{π}}}{{15}}$ (5.5)

Calculate the exterior derivative of omega and integrate over the ball M to obtain the right hand side of Stokes' formula.

 S2 > omega2 := Pullback(G, ExteriorDerivative(omega));
 ${\mathrm{ω2}}{≔}{{\mathrm{sin}}{}\left({\mathrm{φ}}\right)}^{{3}}{}\left({-}{2}{}{{\mathrm{ρ}}}^{{3}}{}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{+}{2}{}{{\mathrm{ρ}}}^{{3}}{}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{3}}{}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{-}{2}{}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){+}{1}\right){}{{\mathrm{ρ}}}^{{4}}{}{\mathrm{drho}}{}{\mathrm{^}}{}{\mathrm{dtheta}}{}{\mathrm{^}}{}{\mathrm{dphi}}$ (5.6)
 B3 > StokesRHS := IntegrateForm(omega2, rho = 0 .. 1, theta = 0 .. 2*Pi, phi = 0 .. Pi);
 ${\mathrm{StokesRHS}}{≔}\frac{{8}{}{\mathrm{π}}}{{15}}$ (5.7)

The homotopy operator for the de Rham complex -- the cylinder construction.

There is a very general approach to the construction of homotopy operators for the exterior derivative base on the "cylinder construction" discussed, for example, in Boothby pages 277--278 (the I operator, Definition 7.10), Flanders pages 27--28 (the K operator) and Spivak  (Volume I) pages 304 --305 (the I operator).

Given a manifold M, let  N = [0, 1] x M  and let i_t : M  -->  N  be the map   i_t(p)  = [t, p].  Then there is a homotopy operator I mapping  (p + 1)-forms theta on N  to p-forms on M and such that

i_1^*(theta) -  i_0(theta) = I(d(theta)) + d(I(theta)).        (*)

To apply this operator in Maple, we use the DeRhamHomotopy command with the option cylindervariable = var, where var is the cylinder coordinate (t) on the manifold N.

The standard application of this homotopy operator is as follows.  Let f, g : M -> M be two smoothly homotopic maps.  This implies that there is a map F : [0, 1] x M -> M such that f = F(t = 0) and g = F(t = 1).  If omega is any closed form on M then, with theta = F^*(omega),  the formula (*) shows that  g^*(omega) - f^*(omega) is exact.

Example.  Consider the case where M = {(x, y, z) such that x^2 + y^2 <> 0} and F(t, x, y, z) = (x, y, t*z).  Formula (*) shows that if omega is a closed 1-form on M, then there is a closed form omega1 on the xy-plane and a globally defined function eta on M such that

omega = omega1 + d(eta).

 B3 > with(DifferentialGeometry):
 B3 > DGsetup([x, y, z], M):
 M > DGsetup([t, x, y, z], N):
 N > ChangeFrame(M):

Define a form omega on M and check that it is closed.

 M > omega := evalDG((-2*x*z^2+y*x^2+y^3+y^4+2*y^2*x^2+x^4)*dx/(x^2+y^2)^2-(2*z^2*y+x^3+x*y^2)*dy/(x^2+y^2)^2+2*z*dz/(x^2+y^2));
 ${\mathrm{ω}}{:=}\frac{\left({-}{2}{}{x}{}{{z}}^{{2}}{+}{y}{}{{x}}^{{2}}{+}{{y}}^{{3}}{+}{{y}}^{{4}}{+}{2}{}{{y}}^{{2}}{}{{x}}^{{2}}{+}{{x}}^{{4}}\right){}{\mathrm{dx}}}{{\left({{x}}^{{2}}{+}{{y}}^{{2}}\right)}^{{2}}}{-}\frac{\left({2}{}{{z}}^{{2}}{}{y}{+}{{x}}^{{3}}{+}{x}{}{{y}}^{{2}}\right){}{\mathrm{dy}}}{{\left({{x}}^{{2}}{+}{{y}}^{{2}}\right)}^{{2}}}{+}\frac{{2}{}{z}{}{\mathrm{dz}}}{{{x}}^{{2}}{+}{{y}}^{{2}}}$ (6.1)
 M > ExteriorDerivative(omega);
 ${0}{}{\mathrm{dx}}{}{\bigwedge }{}{\mathrm{dy}}$ (6.2)

Define the transformation F.

 M > F := Transformation(N, M, [x = x, y = y, z = t*z]);
 ${F}{:=}\left[{x}{=}{x}{,}{y}{=}{y}{,}{z}{=}{t}{}{z}\right]$ (6.3)



Note that at  t = 1,  F  is the identity transformation g  on  M and at  t = 0,  F  is the projection map  f  to the puncture xy-plane R^2-{0}. Define the map  f  and the map   i_0.

 N > f := Transformation(N, M, [x = x, y = y, z = 0]);
 ${f}{:=}\left[{x}{=}{x}{,}{y}{=}{y}{,}{z}{=}{0}\right]$ (6.4)
 N > i_0 := Transformation(M, N, [x = x, y = y, z = z, t = 0]);
 ${\mathrm{i_0}}{:=}\left[{t}{=}{0}{,}{x}{=}{x}{,}{y}{=}{y}{,}{z}{=}{z}\right]$ (6.5)
 M > omega0 := Pullback(i_0, Pullback(f, omega));
 ${\mathrm{ω0}}{:=}\frac{\left({y}{+}{{x}}^{{2}}{+}{{y}}^{{2}}\right){}{\mathrm{dx}}}{{{x}}^{{2}}{+}{{y}}^{{2}}}{-}\frac{{x}{}{\mathrm{dy}}}{{{x}}^{{2}}{+}{{y}}^{{2}}}$ (6.6)

Pullback omega by F and apply the DeRhamHomotopy operator to the result.

 M > omega_t := Pullback(F, omega);
 ${\mathrm{omega_t}}{:=}\frac{{2}{}{t}{}{{z}}^{{2}}{}{\mathrm{dt}}}{{{x}}^{{2}}{+}{{y}}^{{2}}}{-}\frac{\left({2}{}{x}{}{{t}}^{{2}}{}{{z}}^{{2}}{-}{y}{}{{x}}^{{2}}{-}{{y}}^{{3}}{-}{{y}}^{{4}}{-}{2}{}{{y}}^{{2}}{}{{x}}^{{2}}{-}{{x}}^{{4}}\right){}{\mathrm{dx}}}{{\left({{x}}^{{2}}{+}{{y}}^{{2}}\right)}^{{2}}}{-}\frac{\left({2}{}{{t}}^{{2}}{}{{z}}^{{2}}{}{y}{+}{{x}}^{{3}}{+}{x}{}{{y}}^{{2}}\right){}{\mathrm{dy}}}{{\left({{x}}^{{2}}{+}{{y}}^{{2}}\right)}^{{2}}}{+}\frac{{2}{}{{t}}^{{2}}{}{z}{}{\mathrm{dz}}}{{{x}}^{{2}}{+}{{y}}^{{2}}}$ (6.7)
 N > eta := DeRhamHomotopy(omega_t, cylinderconstruction = t);
 ${\mathrm{η}}{:=}\frac{{{z}}^{{2}}}{{{x}}^{{2}}{+}{{y}}^{{2}}}$ (6.8)
 M > ChangeFrame(M);
 ${N}$ (6.9)

We have succeeded in writing omega as the sum of a form in the xy-plane and an exact form on M.

 M > omega &minus (omega0 &plus ExteriorDerivative(eta));
 ${0}{}{\mathrm{dx}}$ (6.10)

Exercises

Exercise 1

Calculate the pullback of the form alpha with respect to the map phi.

 M > with(DifferentialGeometry):
 M > DGsetup([x, y, z], M):
 M > DGsetup([u, v], N):

[i]

 N > phi1 := Transformation(M, N, [u = x/z, v = y/z]);
 ${\mathrm{φ1}}{≔}\left[{u}{=}\frac{{x}}{{z}}{,}{v}{=}\frac{{y}}{{z}}\right]$ (7.1.1)
 M > alpha1 := u^2 + v^2;
 ${\mathrm{α1}}{≔}{{u}}^{{2}}{+}{{v}}^{{2}}$ (7.1.2)

[ii]

 M > phi2 := Transformation(M, N, [u = 3, v = 4]);
 ${\mathrm{φ2}}{≔}\left[{u}{=}{3}{,}{v}{=}{4}\right]$ (7.1.3)
 M > alpha2 := evalDG(du - dv);
 ${\mathrm{α2}}{≔}{\mathrm{du}}{-}{\mathrm{dv}}$ (7.1.4)

[iii]

 N > phi3 := Transformation(M, N, [u = x^2, v = y^2]);
 ${\mathrm{φ3}}{≔}\left[{u}{=}{{x}}^{{2}}{,}{v}{=}{{y}}^{{2}}\right]$ (7.1.5)
 M > alpha3 := evalDG(du - dv);
 ${\mathrm{α3}}{≔}{\mathrm{du}}{-}{\mathrm{dv}}$ (7.1.6)

Solution

Part [i]

 N > Pullback(phi1, alpha1);
 $\frac{{{x}}^{{2}}}{{{z}}^{{2}}}{+}\frac{{{y}}^{{2}}}{{{z}}^{{2}}}$ (7.1.1.1)

Part [ii]

 M > Pullback(phi2, alpha2);
 ${0}{}{\mathrm{dx}}$ (7.1.1.2)

Part [iii]

 M > Pullback(phi3, alpha3);
 ${2}{}{x}{}{\mathrm{dx}}{-}{2}{}{y}{}{\mathrm{dy}}$ (7.1.1.3)

Exercise 2

Use the Pullback command to calculate the Jacobian determinant of the transformation from Cartesian to spherical coordinates.

Solution

The Jacobian determinant can be calculated as the coefficient of the pullback of the standard volume form in Cartesian coordinates.

 M > restart: with(DifferentialGeometry):
 > DGsetup([x, y, z], "cart"):
 cart > DGsetup([rho, phi, theta], "spher"):

Define the coordinate transformation from spherical to Cartesian coordinates.

 spher > T := Transformation("spher", "cart", [x = rho*cos(theta)*sin(phi), y = rho*sin(theta)*sin(phi), z = rho*cos(phi)]);
 ${T}{≔}\left[{x}{=}{\mathrm{ρ}}{}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){,}{y}{=}{\mathrm{ρ}}{}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){,}{z}{=}{\mathrm{ρ}}{}{\mathrm{cos}}{}\left({\mathrm{φ}}\right)\right]$ (7.2.1.1)

Define the standard volume form in Cartesian coordinates with the DGvolume command.

 spher > nu1 := Tools:-DGvolume("form", 1, "cart");
 ${\mathrm{ν1}}{≔}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (7.2.1.2)
 cart > nu2 := Pullback(T, nu1);
 ${\mathrm{ν2}}{≔}{{\mathrm{ρ}}}^{{2}}{}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{\mathrm{drho}}{}{\mathrm{^}}{}{\mathrm{dphi}}{}{\mathrm{^}}{}{\mathrm{dtheta}}$ (7.2.1.3)

Use DGinfo to obtain the coefficient of nu2.

 spher > Tools:-DGinfo(nu2, "CoefficientSet")[1];
 ${{\mathrm{ρ}}}^{{2}}{}{\mathrm{sin}}{}\left({\mathrm{φ}}\right)$ (7.2.1.4)

Exercise 3

A mapping phi : M -> N is a local submersion if phi_* is a surjective linear map, or, equivalently, if phi^* is injective.

Determine those points at which the following map phi fails to be submersion.

 spher > restart: with(DifferentialGeometry):
 > DGsetup([x, y, z, w], M):
 M > DGsetup([u, v], N):
 N > phi := Transformation(M, N, [u = x*y + z*w, v = x*z + y*w]);
 ${\mathrm{φ}}{≔}\left[{u}{=}{x}{}{y}{+}{z}{}{w}{,}{v}{=}{x}{}{z}{+}{y}{}{w}\right]$ (7.3.1)

Solution

If phi^* is injective, then linearly independent forms pullback to linearly independent forms.  So phi fails to be a local submersion precisely at the points where phi^*(du &w dv) vanishes.

 M > omega := Pullback(phi, du &w dv);
 ${\mathrm{ω}}{≔}\left({-}{x}{}{z}{+}{y}{}{w}\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{+}\left({-}{z}{}{w}{+}{x}{}{y}\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}\left({-}{{z}}^{{2}}{+}{{y}}^{{2}}\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dw}}{+}\left({-}{{w}}^{{2}}{+}{{x}}^{{2}}\right){}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}\left({-}{z}{}{w}{+}{x}{}{y}\right){}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dw}}{+}\left({-}{x}{}{z}{+}{y}{}{w}\right){}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.3.1.1)

Set the coefficients of omega to zero and solve the resulting set of equations.

 M > Eq := Tools:-DGinfo(omega, "CoefficientSet");
 ${\mathrm{Eq}}{≔}\left\{{-}{z}{}{w}{+}{x}{}{y}{,}{-}{{z}}^{{2}}{+}{{y}}^{{2}}{,}{-}{{w}}^{{2}}{+}{{x}}^{{2}}{,}{-}{x}{}{z}{+}{y}{}{w}\right\}$ (7.3.1.2)
 M > solve(Eq, {x, u, z, w});
 $\left\{{w}{=}{w}{,}{u}{=}{u}{,}{x}{=}{w}{,}{z}{=}{y}\right\}{,}\left\{{w}{=}{w}{,}{u}{=}{u}{,}{x}{=}{-}{w}{,}{z}{=}{-}{y}\right\}$ (7.3.1.3)

The map phi fails to be a submersion on a transverse pair of 2-planes.

Exercise 4

 M > restart: with(DifferentialGeometry):

[i]  Show that the map Sigma1 defines an integral manifold for the EDS Omega1 (from Bryant, Chern et al.  Exterior Differential Systems, page 53).

 > DGsetup([phi], N):
 N > DGsetup([x, y, z, phi], M):
 M > Omega1 := evalDG([dy - sin(phi)*dx, dz - cos(phi)*dx]);
 ${\mathrm{Ω1}}{≔}\left[{-}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{\mathrm{dx}}{+}{\mathrm{dy}}{,}{-}{\mathrm{cos}}{}\left({\mathrm{φ}}\right){}{\mathrm{dx}}{+}{\mathrm{dz}}\right]$ (7.4.1)
 M > Sigma1 := Transformation(N, M, [x = diff(f(phi), phi$2) + f(phi), y = sin(phi)*diff(f(phi), phi$2) - cos(phi)*diff(f(phi), phi), z = cos(phi)*diff(f(phi), phi\$2) + sin(phi)*diff(f(phi), phi), phi = phi]);
 ${\mathrm{Σ1}}{≔}\left[{x}{=}\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{\mathrm{φ}}}^{{2}}}{}{f}{}\left({\mathrm{φ}}\right){+}{f}{}\left({\mathrm{φ}}\right){,}{y}{=}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{\mathrm{φ}}}^{{2}}}{}{f}{}\left({\mathrm{φ}}\right)\right){-}{\mathrm{cos}}{}\left({\mathrm{φ}}\right){}\left(\frac{{ⅆ}}{{ⅆ}{\mathrm{φ}}}{}{f}{}\left({\mathrm{φ}}\right)\right){,}{z}{=}{\mathrm{cos}}{}\left({\mathrm{φ}}\right){}\left(\frac{{{ⅆ}}^{{2}}}{{ⅆ}{{\mathrm{φ}}}^{{2}}}{}{f}{}\left({\mathrm{φ}}\right)\right){+}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}\left(\frac{{ⅆ}}{{ⅆ}{\mathrm{φ}}}{}{f}{}\left({\mathrm{φ}}\right)\right){,}{\mathrm{φ}}{=}{\mathrm{φ}}\right]$ (7.4.2)

[ii]  Find the integral manifolds for the EDS Omega2, assuming that u, v and q are functions of x and y.

 N > DGsetup([x, y], N):
 N > DGsetup([x, y, u, v, q], M):
 M > Omega2 := evalDG([du - q*dy, dv + q*dx]);
 ${\mathrm{Ω2}}{≔}\left[{-}{q}{}{\mathrm{dy}}{+}{\mathrm{du}}{,}{q}{}{\mathrm{dx}}{+}{\mathrm{dv}}\right]$ (7.4.3)

Solution

Part [i]  Simply pullback the differential forms in Omega1 by Sigma1 and check that the results are zero forms.

 M > Pullback(Sigma1, Omega1);
 $\left[{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}\right]$ (7.4.1.1)

Part [ii]  Define a transformation Sigma2 from N to M with the coordinates u ,v, and w as arbitrary functions of x and y.

 N > Sigma2 := Transformation(N, M, [x = x, y = y, u = f(x, y), v = g(x, y), q = h(x, y)]);
 ${\mathrm{Σ2}}{≔}\left[{x}{=}{x}{,}{y}{=}{y}{,}{u}{=}{f}{}\left({x}{,}{y}\right){,}{v}{=}{g}{}\left({x}{,}{y}\right){,}{q}{=}{h}{}\left({x}{,}{y}\right)\right]$ (7.4.1.2)

Pullback the forms in Omega2 by Sigma2 and extract the coefficients of the results.

 N > Theta := Pullback(Sigma2, Omega2);
 ${\mathrm{Θ}}{≔}\left[\left(\frac{{\partial }}{{\partial }{x}}{}{f}{}\left({x}{,}{y}\right)\right){}{\mathrm{dx}}{+}\left(\frac{{\partial }}{{\partial }{y}}{}{f}{}\left({x}{,}{y}\right){-}{h}{}\left({x}{,}{y}\right)\right){}{\mathrm{dy}}{,}\left(\frac{{\partial }}{{\partial }{x}}{}{g}{}\left({x}{,}{y}\right){+}{h}{}\left({x}{,}{y}\right)\right){}{\mathrm{dx}}{+}\left(\frac{{\partial }}{{\partial }{y}}{}{g}{}\left({x}{,}{y}\right)\right){}{\mathrm{dy}}\right]$ (7.4.1.3)
 N > Eq := map(op, map(Tools:-DGinfo, Theta, "CoefficientSet"));
 ${\mathrm{Eq}}{≔}\left[\frac{{\partial }}{{\partial }{x}}{}{f}{}\left({x}{,}{y}\right){,}\frac{{\partial }}{{\partial }{y}}{}{f}{}\left({x}{,}{y}\right){-}{h}{}\left({x}{,}{y}\right){,}\frac{{\partial }}{{\partial }{y}}{}{g}{}\left({x}{,}{y}\right){,}\frac{{\partial }}{{\partial }{x}}{}{g}{}\left({x}{,}{y}\right){+}{h}{}\left({x}{,}{y}\right)\right]$ (7.4.1.4)

Use pdsolve to solve the pde in the list Eq.

 N > Soln := pdsolve(Eq, {f, g, h});
 ${\mathrm{Soln}}{≔}\left\{{f}{}\left({x}{,}{y}\right){=}{\mathrm{_C1}}{}{y}{+}{\mathrm{_C2}}{,}{g}{}\left({x}{,}{y}\right){=}{-}{\mathrm{_C1}}{}{x}{+}{\mathrm{_C3}}{,}{h}{}\left({x}{,}{y}\right){=}{\mathrm{_C1}}\right\}$ (7.4.1.5)

Back substitute this solution into Sigma2.  Check that Sigma3 is an integral manifold.

 N > Sigma3 := eval(Sigma2, Soln);
 ${\mathrm{Σ3}}{≔}\left[{x}{=}{x}{,}{y}{=}{y}{,}{u}{=}{\mathrm{_C1}}{}{y}{+}{\mathrm{_C2}}{,}{v}{=}{-}{\mathrm{_C1}}{}{x}{+}{\mathrm{_C3}}{,}{q}{=}{\mathrm{_C1}}\right]$ (7.4.1.6)
 N > Pullback(Sigma3, Omega2);
 $\left[{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}\right]$ (7.4.1.7)

Exercise 5

Write a program to verify, by example, the following properties of the pullback map:

[i]  phi^*(alpha)(X_p, Y_p) = alpha(phi_*(X_p), phi_*(Y_p)), where alpha is a 2-form.

[ii]  phi^*(alpha &w beta) = phi^*(alpha) &w phi^*(beta)

[iii]  phi^(d(alpha)) = d(phi^*(alpha))

Use the following data to test your programs.

 N > restart: with(DifferentialGeometry):
 > DGsetup([x, y, z], M):
 M > DGsetup([u, v, w], N):
 N > alpha1 := evalDG(w*du &w dv + u*v*dv &w dw);
 ${\mathrm{α1}}{≔}{w}{}{\mathrm{du}}{}{\mathrm{^}}{}{\mathrm{dv}}{+}{u}{}{v}{}{\mathrm{dv}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.5.1)
 N > alpha2 := evalDG(u*dv - v^2*dw);
 ${\mathrm{α2}}{≔}{u}{}{\mathrm{dv}}{-}{{v}}^{{2}}{}{\mathrm{dw}}$ (7.5.2)
 N > alpha3 := evalDG(u*v*du - w^2*dv);
 ${\mathrm{α3}}{≔}{u}{}{v}{}{\mathrm{du}}{-}{{w}}^{{2}}{}{\mathrm{dv}}$ (7.5.3)
 N > phi := Transformation(M, N, [u = x/y, v = y/z, w = x*y/z]);
 ${\mathrm{φ}}{≔}\left[{u}{=}\frac{{x}}{{y}}{,}{v}{=}\frac{{y}}{{z}}{,}{w}{=}\frac{{x}{}{y}}{{z}}\right]$ (7.5.4)
 M > X := y*D_x + z*D_y - x^2*D_z;
 ${X}{≔}{y}{}{\mathrm{D_x}}{+}{z}{}{\mathrm{D_y}}{-}{{x}}^{{2}}{}{\mathrm{D_z}}$ (7.5.5)
 M > Y := evalDG(z*y*D_x + y*D_y + x^2*D_z);
 ${Y}{≔}{z}{}{y}{}{\mathrm{D_x}}{+}{y}{}{\mathrm{D_y}}{+}{{x}}^{{2}}{}{\mathrm{D_z}}$ (7.5.6)
 M > pt1 := [x = 1, y = 2, z = 3];
 ${\mathrm{pt1}}{≔}\left[{x}{=}{1}{,}{y}{=}{2}{,}{z}{=}{3}\right]$ (7.5.7)
 M > pt2 := [x = 3, y = 1, z = -2];
 ${\mathrm{pt2}}{≔}\left[{x}{=}{3}{,}{y}{=}{1}{,}{z}{=}{-}{2}\right]$ (7.5.8)

Solution

Part [i]

 N > PullbackDefinition := proc(phi, alpha, X, Y, pt)
 N > local a, a1, a2, a3, a4, b, b1, b2, b3, b4, c;
 N > a1 := Pullback(phi, alpha);
 N > a2 := eval(a1, pt);
 N > a3 := eval(X, pt);
 N > a4 := eval(Y, pt);
 N > a := Hook([a3, a4], a2);
 N > b1 := Pushforward(phi, a3, pt);
 N > b2 := Pushforward(phi, a4, pt);
 N > b3 := ApplyTransformation(phi, pt);
 N > b4 := eval(alpha, b3);
 N > b := Hook([b1, b2], b4);
 N > a - b
 M > end:
 M >
 M > PullbackDefinition(phi, alpha1, X, Y, pt1);
 ${0}$ (7.5.1.1)
 N > PullbackDefinition(phi, alpha1, X, Y, pt2);
 ${0}$ (7.5.1.2)

Part [ii]

 N > PullbackHomomorphism := proc(phi, alpha, beta)
 N > local a1, a, b1, b2, b;
 N > a1 := alpha &wedge beta;
 N > a := Pullback(phi, a1):
 N > b1 := Pullback(phi, alpha);
 N > b2 := Pullback(phi, beta);
 N > b := b1 &wedge b2;
 N > a &minus b;
 N > end:
 N >
 N > PullbackHomomorphism(phi, alpha1, alpha2);
 ${0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (7.5.1.3)
 M > PullbackHomomorphism(phi, alpha2, alpha3);
 ${0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}$ (7.5.1.4)

Part [iii]

 N > PullbackExteriorDerivative := proc(phi, alpha)
 N > local a1, a, b1 ,b;
 N > a1 := ExteriorDerivative(alpha);
 N > a := Pullback(phi, a1);
 N > b1 := Pullback(phi, alpha);
 N > b := ExteriorDerivative(b1);
 N > a &minus b;
 M > end:
 >
 M > PullbackExteriorDerivative(phi, alpha1);
 ${0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (7.5.1.5)
 M > PullbackExteriorDerivative(phi, alpha2);
 ${0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}$ (7.5.1.6)

Exercise 6

Use the Pullback command to calculate the Maurer-Cartan forms for the matrix group defined by the matrix A.  (See Lesson 5 and Lesson 7 Ex. 7.)

 M > with(DifferentialGeometry):
 M > DGsetup([x1, x2, x3], G):
 M > A := Matrix([[exp(-x1), -x1*exp(-x1), x2], [0, exp(-x1), x3], [0, 0, 1]]);
 ${A}{≔}\left[\begin{array}{ccc}{{ⅇ}}^{{-}{\mathrm{x1}}}& {-}{\mathrm{x1}}{}{{ⅇ}}^{{-}{\mathrm{x1}}}& {\mathrm{x2}}\\ {0}& {{ⅇ}}^{{-}{\mathrm{x1}}}& {\mathrm{x3}}\\ {0}& {0}& {1}\end{array}\right]$ (7.6.1)

Solution

We build upon the techniques used in Lesson 7 Ex. 7.  If L_a(x) = a*x denotes the left-multiplication map, then a form omega is left invariant if (L_a)*(omega(a*x)) = omega(x).  In this equation, replace x by a and a by a^(-1) to get omega(a) = L_(a^-1) (omega(e)) -- this formula gives omega(a) in terms of the value of omega(e).

Recall that the group multiplication is given by

 G > MultiplicationRule := [z3 = (y3 + x3*exp(x1))/exp(x1), z2 = (y2 - x1*y3 + x2*exp(x1))/exp(x1), z1 = x1 + y1];
 ${\mathrm{MultiplicationRule}}{≔}\left[{\mathrm{z3}}{=}\frac{{\mathrm{y3}}{+}{\mathrm{x3}}{}{{ⅇ}}^{{\mathrm{x1}}}}{{{ⅇ}}^{{\mathrm{x1}}}}{,}{\mathrm{z2}}{=}\frac{{\mathrm{y2}}{-}{\mathrm{x1}}{}{\mathrm{y3}}{+}{\mathrm{x2}}{}{{ⅇ}}^{{\mathrm{x1}}}}{{{ⅇ}}^{{\mathrm{x1}}}}{,}{\mathrm{z1}}{=}{\mathrm{x1}}{+}{\mathrm{y1}}\right]$ (7.6.1.1)

The inverse of [x1, x2, x3] is given by

 G > InverseRule := [y1 = -x1, y2 = -x1*x3*exp(x1) - x2*exp(x1), y3 = -x3*exp(x1)];
 ${\mathrm{InverseRule}}{≔}\left[{\mathrm{y1}}{=}{-}{\mathrm{x1}}{,}{\mathrm{y2}}{=}{-}{\mathrm{x1}}{}{\mathrm{x3}}{}{{ⅇ}}^{{\mathrm{x1}}}{-}{\mathrm{x2}}{}{{ⅇ}}^{{\mathrm{x1}}}{,}{\mathrm{y3}}{=}{-}{\mathrm{x3}}{}{{ⅇ}}^{{\mathrm{x1}}}\right]$ (7.6.1.2)

Here is the left multiplication map by the inverse of [a1, a2, a3].

 G > multL := simplify(eval(eval(MultiplicationRule,[x1 = -a1, x2 = -a1*a3*ex(a1) -a2*exp(a1), x3 = -a3*exp(a1)]),[y1 = x1, y2 = x2, y3 = x3]));
 ${\mathrm{multL}}{≔}\left[{\mathrm{z3}}{=}{-}\left({-}{\mathrm{x3}}{+}{\mathrm{a3}}\right){}{{ⅇ}}^{{\mathrm{a1}}}{,}{\mathrm{z2}}{=}{-}\left({-}{\mathrm{x2}}{-}{\mathrm{a1}}{}{\mathrm{x3}}{+}{{ⅇ}}^{{-}{\mathrm{a1}}}{}{\mathrm{a1}}{}{\mathrm{a3}}{}{\mathrm{ex}}{}\left({\mathrm{a1}}\right){+}{\mathrm{a2}}\right){}{{ⅇ}}^{{\mathrm{a1}}}{,}{\mathrm{z1}}{=}{-}{\mathrm{a1}}{+}{\mathrm{x1}}\right]$ (7.6.1.3)
 G > LeftMultByInverse := Transformation(G, G, eval(multL, [z1 = x1, z2 = x2, z3 = x3]));
 ${\mathrm{LeftMultByInverse}}{≔}\left[{\mathrm{x1}}{=}{-}{\mathrm{a1}}{+}{\mathrm{x1}}{,}{\mathrm{x2}}{=}{-}\left({-}{\mathrm{x2}}{-}{\mathrm{a1}}{}{\mathrm{x3}}{+}{{ⅇ}}^{{-}{\mathrm{a1}}}{}{\mathrm{a1}}{}{\mathrm{a3}}{}{\mathrm{ex}}{}\left({\mathrm{a1}}\right){+}{\mathrm{a2}}\right){}{{ⅇ}}^{{\mathrm{a1}}}{,}{\mathrm{x3}}{=}{-}\left({-}{\mathrm{x3}}{+}{\mathrm{a3}}\right){}{{ⅇ}}^{{\mathrm{a1}}}\right]$ (7.6.1.4)

Here are the left invariant 1-forms at [a1, a2, a3].

 G > OmegaLatA := eval(Pullback(LeftMultByInverse, [dx1, dx2, dx3]), [x1 = 0, x2 = 0, x3 = 0]);
 ${\mathrm{OmegaLatA}}{≔}\left[{\mathrm{dx1}}{,}{{ⅇ}}^{{\mathrm{a1}}}{}{\mathrm{dx2}}{+}{\mathrm{a1}}{}{{ⅇ}}^{{\mathrm{a1}}}{}{\mathrm{dx3}}{,}{{ⅇ}}^{{\mathrm{a1}}}{}{\mathrm{dx3}}\right]$ (7.6.1.5)

Here are the left invariant 1-forms at [x1, x2, x3].

 G > OmegaL := eval(OmegaLatA, [a1 = x1, a2 = x2, a3 = x3]);
 ${\mathrm{OmegaL}}{≔}\left[{\mathrm{dx1}}{,}{{ⅇ}}^{{\mathrm{x1}}}{}{\mathrm{dx2}}{+}{\mathrm{x1}}{}{{ⅇ}}^{{\mathrm{x1}}}{}{\mathrm{dx3}}{,}{{ⅇ}}^{{\mathrm{x1}}}{}{\mathrm{dx3}}\right]$ (7.6.1.6)

These are the same forms as those found in Exercise 5.  The method in this exercise can be used when the Lie group is not given as a matrix group.

Now we calculate the right invariant forms.

 G > multR := simplify(eval(MultiplicationRule, [y1 = -a1, y2 = -a1*a3*exp(a1) - a2*exp(a1), y3 = -a3*exp(a1)]));
 ${\mathrm{multR}}{≔}\left[{\mathrm{z3}}{=}{-}\left({\mathrm{a3}}{}{{ⅇ}}^{{\mathrm{a1}}}{-}{\mathrm{x3}}{}{{ⅇ}}^{{\mathrm{x1}}}\right){}{{ⅇ}}^{{-}{\mathrm{x1}}}{,}{\mathrm{z2}}{=}{-}\left({\mathrm{a1}}{}{\mathrm{a3}}{}{{ⅇ}}^{{\mathrm{a1}}}{+}{\mathrm{a2}}{}{{ⅇ}}^{{\mathrm{a1}}}{-}{\mathrm{x1}}{}{\mathrm{a3}}{}{{ⅇ}}^{{\mathrm{a1}}}{-}{\mathrm{x2}}{}{{ⅇ}}^{{\mathrm{x1}}}\right){}{{ⅇ}}^{{-}{\mathrm{x1}}}{,}{\mathrm{z1}}{=}{-}{\mathrm{a1}}{+}{\mathrm{x1}}\right]$ (7.6.1.7)
 G > RightMultByInverse := Transformation(G, G, eval(multR, [z1 = x1, z2 = x2, z3 = x3]));
 ${\mathrm{RightMultByInverse}}{≔}\left[{\mathrm{x1}}{=}{-}{\mathrm{a1}}{+}{\mathrm{x1}}{,}{\mathrm{x2}}{=}{-}\left({\mathrm{a1}}{}{\mathrm{a3}}{}{{ⅇ}}^{{\mathrm{a1}}}{+}{\mathrm{a2}}{}{{ⅇ}}^{{\mathrm{a1}}}{-}{\mathrm{x1}}{}{\mathrm{a3}}{}{{ⅇ}}^{{\mathrm{a1}}}{-}{\mathrm{x2}}{}{{ⅇ}}^{{\mathrm{x1}}}\right){}{{ⅇ}}^{{-}{\mathrm{x1}}}{,}{\mathrm{x3}}{=}{-}\left({\mathrm{a3}}{}{{ⅇ}}^{{\mathrm{a1}}}{-}{\mathrm{x3}}{}{{ⅇ}}^{{\mathrm{x1}}}\right){}{{ⅇ}}^{{-}{\mathrm{x1}}}\right]$ (7.6.1.8)
 G > OmegaRatA := eval(Pullback(RightMultByInverse, [dx1, dx2, dx3]), [x1 = 0, x2 = 0, x3 = 0]);
 ${\mathrm{OmegaRatA}}{≔}\left[{\mathrm{dx1}}{,}{{ⅇ}}^{{\mathrm{a1}}}{}\left({\mathrm{a3}}{+}{\mathrm{a1}}{}{\mathrm{a3}}{+}{\mathrm{a2}}\right){}{\mathrm{dx1}}{+}{\mathrm{dx2}}{,}{\mathrm{a3}}{}{{ⅇ}}^{{\mathrm{a1}}}{}{\mathrm{dx1}}{+}{\mathrm{dx3}}\right]$ (7.6.1.9)
 G > OmegaR := eval(OmegaRatA, [a1 = x1, a2 = x2, a3 = x3]);
 ${\mathrm{OmegaR}}{≔}\left[{\mathrm{dx1}}{,}{{ⅇ}}^{{\mathrm{x1}}}{}\left({\mathrm{x3}}{+}{\mathrm{x1}}{}{\mathrm{x3}}{+}{\mathrm{x2}}\right){}{\mathrm{dx1}}{+}{\mathrm{dx2}}{,}{\mathrm{x3}}{}{{ⅇ}}^{{\mathrm{x1}}}{}{\mathrm{dx1}}{+}{\mathrm{dx3}}\right]$ (7.6.1.10)

Exercise 7

 G > restart: with(DifferentialGeometry):
 > DGsetup([x,y,z,w], R4):

[i]  Compute the line integral of the 1-form omega1 along the curve C defined by y = x^2 - x, z = x^3 - x^2 + x, w = x^4 - x^3 + x^2 - x from x = -1 ... 1.

 R4 > omega1 := evalDG(z*x*dx + x*w*dy + y*w*dz + x*y*dw);
 ${\mathrm{ω1}}{≔}{z}{}{x}{}{\mathrm{dx}}{+}{x}{}{w}{}{\mathrm{dy}}{+}{y}{}{w}{}{\mathrm{dz}}{+}{x}{}{y}{}{\mathrm{dw}}$ (7.7.1)

[ii]  Compute the surface integral of the 2-form omega2 over the torus T in R4 defined by x^2 + y ^2 = 1, z^2 + w^2 = 1.

 R4 > omega2 := evalDG(z^2*dx &w dy + w^2*dx &w dz + y^2*dx &w dw + w^2*dy &w dz + x*z*dy &w dw + y*z*dz &w dw);
 ${\mathrm{ω2}}{≔}{{z}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{+}{{w}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}{{y}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dw}}{+}{{w}}^{{2}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}{z}{}{x}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dw}}{+}{y}{}{z}{}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.7.2)

[iii]  Compute the triple integral of the 3-form omega3 over the 3 dimensional sphere x^2 + y^2 + z^2 + w^2 = 1. Note that omega3 is closed.

 R4 > omega3 := evalDG(z*dx &w dy &w dw);
 ${\mathrm{ω3}}{≔}{z}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.7.3)
 R4 > ExteriorDerivative(omega3);
 ${\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.7.4)

Solution

Part [i]  Parameterize the curve C with the coordinate x, pullback omega1 and integrate with respect to x from -1 to 1.

 R4 > DGsetup([x], N):
 N > C := Transformation(N, R4, [x = x, y = x^2 - x, z = x^3 - x^2 + x, w = x^4 - x^3 + x^2 - x]);
 ${C}{≔}\left[{x}{=}{x}{,}{y}{=}{{x}}^{{2}}{-}{x}{,}{z}{=}{{x}}^{{3}}{-}{{x}}^{{2}}{+}{x}{,}{w}{=}{{x}}^{{4}}{-}{{x}}^{{3}}{+}{{x}}^{{2}}{-}{x}\right]$ (7.7.1.1)
 N > eta := Pullback(C, omega1);
 ${\mathrm{η}}{≔}\left({17}{}{{x}}^{{6}}{-}{22}{}{{x}}^{{5}}{+}{18}{}{{x}}^{{4}}{-}{11}{}{{x}}^{{3}}{+}{4}{}{{x}}^{{2}}{+}{3}{}{{x}}^{{8}}{-}{8}{}{{x}}^{{7}}\right){}{\mathrm{dx}}$ (7.7.1.2)
 N > IntegrateForm(eta, x = -1 .. 1);
 $\frac{{1616}}{{105}}$ (7.7.1.3)

Part [ii]  Parameterize the torus T with the angular coordinates theta and phi, then pullback omega2 and integrate.

 N > DGsetup([theta, phi], N):
 N > S := Transformation(N, R4, [x = sin(theta), y = cos(theta), z = cos(phi), w = sin(phi)]);
 ${S}{≔}\left[{x}{=}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){,}{y}{=}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){,}{z}{=}{\mathrm{cos}}{}\left({\mathrm{φ}}\right){,}{w}{=}{\mathrm{sin}}{}\left({\mathrm{φ}}\right)\right]$ (7.7.1.4)
 N > eta := Pullback(S, omega2);
 ${\mathrm{η}}{≔}\left({-}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{+}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{2}}{+}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){-}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}{+}{{\mathrm{cos}}{}\left({\mathrm{θ}}\right)}^{{3}}{}{\mathrm{cos}}{}\left({\mathrm{φ}}\right){-}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){+}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){}{\mathrm{sin}}{}\left({\mathrm{φ}}\right){}{{\mathrm{cos}}{}\left({\mathrm{φ}}\right)}^{{2}}\right){}{\mathrm{dtheta}}{}{\mathrm{^}}{}{\mathrm{dphi}}$ (7.7.1.5)
 N > IntegrateForm(eta, theta = 0 .. 2*Pi, phi = 0 .. 2*Pi);
 ${-}{{\mathrm{π}}}^{{2}}$ (7.7.1.6)

Part [iii]  By Stokes Theorem the value of the integral is 0.  We check this by a direct computation.

 N > DGsetup([theta1, theta2, theta3], N):
 N > V := Transformation(N, R4, [x = cos(theta1)*sin(theta2)*sin(theta3), y = sin(theta1)*sin(theta2)*sin(theta3), z = cos(theta2)*sin(theta3), w = cos(theta3)]);
 ${V}{≔}\left[{x}{=}{\mathrm{cos}}{}\left({\mathrm{θ1}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ2}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ3}}\right){,}{y}{=}{\mathrm{sin}}{}\left({\mathrm{θ1}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ2}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ3}}\right){,}{z}{=}{\mathrm{cos}}{}\left({\mathrm{θ2}}\right){}{\mathrm{sin}}{}\left({\mathrm{θ3}}\right){,}{w}{=}{\mathrm{cos}}{}\left({\mathrm{θ3}}\right)\right]$ (7.7.1.7)
 N > eta := Pullback(V, z*dx &w dy &w dw);
 ${\mathrm{η}}{≔}{{\mathrm{cos}}{}\left({\mathrm{θ2}}\right)}^{{2}}{}{{\mathrm{sin}}{}\left({\mathrm{θ3}}\right)}^{{4}}{}{\mathrm{sin}}{}\left({\mathrm{θ2}}\right){}{\mathrm{dtheta1}}{}{\mathrm{^}}{}{\mathrm{dtheta2}}{}{\mathrm{^}}{}{\mathrm{dtheta3}}$ (7.7.1.8)
 N > IntegrateForm(eta, theta1 = 0 .. 2*Pi, theta2 = 0 .. 2*Pi, theta3 = 0 .. Pi);
 ${0}$ (7.7.1.9)

Exercise 8

 N > restart: with(DifferentialGeometry):
 > DGsetup([x, y, z], R3):
 R3 > DGsetup([x, y, z, w], R4):

[i]  Use Stokes theorem to integrate the 2-form omega1 over the closed cylinder x^2 + y^2 = 1 with top z = 1 and bottom z = 0.

 R4 > ChangeFrame(R3):
 R3 > omega1 := evalDG((x + 2*z)*dx &w dy + (z - x + y) &w dx &w dz + (x + 3*z)*dy &w dz);
 ${\mathrm{ω1}}{≔}\left({x}{+}{2}{}{z}\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{+}\left({z}{-}{x}{+}{y}\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}\left({x}{+}{3}{}{z}\right){}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (7.8.1)

[ii]  Use Stokes theorem to integrate the 3-form omega2 over the surface of the unit cube in 4 dimensions.

 R3 > ChangeFrame(R4):
 R4 > omega2 := evalDG(w^2*dx &w dy &w dz - x^2*dy &w dz &w dw + z^2*dx &w dy &w dw + y^2*dx &w dz &w dw);
 ${\mathrm{ω2}}{≔}{{w}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{+}{{z}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dw}}{+}{{y}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}{-}{{x}}^{{2}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.8.2)

Solution

Part [i]  We use cylindrical coordinates to integrate over the solid cylinder.

 R4 > DGsetup([r, theta, z], N3):
 N3 > phi := Transformation(N3, R3, [x = r*cos(theta), y = r*sin(theta), z = z]);
 ${\mathrm{φ}}{≔}\left[{x}{=}{r}{}{\mathrm{cos}}{}\left({\mathrm{θ}}\right){,}{y}{=}{r}{}{\mathrm{sin}}{}\left({\mathrm{θ}}\right){,}{z}{=}{z}\right]$ (7.8.1.1)
 N3 > zeta := ExteriorDerivative(omega1);
 ${\mathrm{ζ}}{≔}{2}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (7.8.1.2)

Convert to cylindrical coordinates.

 R3 > eta := Pullback(phi, zeta);
 ${\mathrm{η}}{≔}{2}{}{r}{}{\mathrm{dr}}{}{\mathrm{^}}{}{\mathrm{dtheta}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (7.8.1.3)
 N3 > IntegrateForm(eta, r = 0 .. 1, theta = 0 .. 2*Pi, z = 0 .. 1);
 ${2}{}{\mathrm{π}}$ (7.8.1.4)

Part [ii]  We integrate the exterior derivative of omega2 over the solid cube.

 N3 > zeta := ExteriorDerivative(omega2);
 ${\mathrm{ζ}}{≔}\left({-}{2}{}{x}{-}{2}{}{y}{+}{2}{}{z}{-}{2}{}{w}\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}{}{\mathrm{^}}{}{\mathrm{dw}}$ (7.8.1.5)
 R4 > IntegrateForm(zeta, x = 0 .. 1, y = 0 .. 1, z = 0 .. 1, w = 0 .. 1);
 ${-}{2}$ (7.8.1.6)

Exercise 9

Show that all of the following 1-forms, defined on the punctured plane are closed but that, by the de Rham theorem, only three are exact.

Hint: Integrate the forms over the unit circle -- by Stokes theorem the answer is zero, if the form is exact, and the de Rham theorem implies that the converse is true.

 R4 > DGsetup([x, y], M):
 M > omega1 := 4*x^3/(y^4 + x^4)*dx + 4*y^3/(y^4 + x^4)*dy;
 ${\mathrm{ω1}}{≔}\frac{{4}{}{{x}}^{{3}}{}{\mathrm{dx}}}{{{y}}^{{4}}{+}{{x}}^{{4}}}{+}\frac{{4}{}{{y}}^{{3}}{}{\mathrm{dy}}}{{{y}}^{{4}}{+}{{x}}^{{4}}}$ (7.9.1)
 M > omega2 := 2*x*y^2/(y^4 + x^4)*dx - 2*x^2*y/(y^4 + x^4)*dy;
 ${\mathrm{ω2}}{≔}\frac{{2}{}{x}{}{{y}}^{{2}}{}{\mathrm{dx}}}{{{y}}^{{4}}{+}{{x}}^{{4}}}{-}\frac{{2}{}{{x}}^{{2}}{}{y}{}{\mathrm{dy}}}{{{y}}^{{4}}{+}{{x}}^{{4}}}$ (7.9.2)
 M > omega3 := 3*x^2*y^3/(y^6 + x^6)*dx - 3*x^3*y^2/(y^6 + x^6)*dy;
 ${\mathrm{ω3}}{≔}\frac{{3}{}{{x}}^{{2}}{}{{y}}^{{3}}{}{\mathrm{dx}}}{{{y}}^{{6}}{+}{{x}}^{{6}}}{-}\frac{{3}{}{{x}}^{{3}}{}{{y}}^{{2}}{}{\mathrm{dy}}}{{{y}}^{{6}}{+}{{x}}^{{6}}}$ (7.9.3)
 M > omega4 := 2*x*y^4/(x^2 + y^2)^2*dx + 2*y*x^4/(x^2 + y^2)^2*dy;
 ${\mathrm{ω4}}{≔}\frac{{2}{}{x}{}{{y}}^{{4}}{}{\mathrm{dx}}}{{\left({{x}}^{{2}}{+}{{y}}^{{2}}\right)}^{{2}}}{+}\frac{{2}{}{y}{}{{x}}^{{4}}{}{\mathrm{dy}}}{{\left({{x}}^{{2}}{+}{{y}}^{{2}}\right)}^{{2}}}$ (7.9.4)

Solution

First, we check that the forms in the list Omega are all closed.

 M > Omega := [omega1, omega2, omega3, omega4]:
 M > ExteriorDerivative(Omega);
 $\left[{0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{,}{0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{,}{0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{,}{0}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}\right]$ (7.9.1.1)

Set up a parameterization of the unit circle.

 M > DGsetup([t], N):
 N > C := Transformation(N, M, [x = cos(t), y = sin(t)]);
 ${C}{≔}\left[{x}{=}{\mathrm{cos}}{}\left({t}\right){,}{y}{=}{\mathrm{sin}}{}\left({t}\right)\right]$ (7.9.1.2)

Integrate each of the forms in Omega around the unit circle.

 N > Theta := Pullback(C, Omega);
 ${\mathrm{Θ}}{≔}\left[{-}\frac{{4}{}{\mathrm{sin}}{}\left({t}\right){}{\mathrm{cos}}{}\left({t}\right){}\left({2}{}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}{-}{1}\right){}{\mathrm{dt}}}{{2}{}{{\mathrm{cos}}{}\left({t}\right)}^{{4}}{+}{1}{-}{2}{}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}}{,}{-}\frac{{2}{}{\mathrm{sin}}{}\left({t}\right){}{\mathrm{cos}}{}\left({t}\right){}{\mathrm{dt}}}{{2}{}{{\mathrm{cos}}{}\left({t}\right)}^{{4}}{+}{1}{-}{2}{}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}}{,}{-}\frac{{3}{}{{\mathrm{sin}}{}\left({t}\right)}^{{2}}{}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}{}{\mathrm{dt}}}{{1}{-}{3}{}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}{+}{3}{}{{\mathrm{cos}}{}\left({t}\right)}^{{4}}}{,}{2}{}{\mathrm{sin}}{}\left({t}\right){}{\mathrm{cos}}{}\left({t}\right){}\left({2}{}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}{-}{1}\right){}{\mathrm{dt}}\right]$ (7.9.1.3)
 N > map(IntegrateForm, Theta, t = 0 .. 2*Pi);
 $\left[{0}{,}{0}{,}{-}{2}{}{\mathrm{π}}{,}{0}\right]$ (7.9.1.4)

The forms omega1, omega2, and omega4 are all exact -- in fact, we can write them as the exterior derivatives of globally defined functions using the DeRhamHomotopy command.

 N > eta1 := DeRhamHomotopy(omega1, initialpoint = [x = 1, y = 0], path = "zigzag");
 ${\mathrm{η1}}{≔}{\mathrm{ln}}{}\left(\frac{{{y}}^{{4}}{+}{{x}}^{{4}}}{{{x}}^{{4}}}\right){+}\frac{{4}{}{\mathrm{ln}}{}\left({x}\right){}{x}}{{x}{-}{1}}{-}\frac{{4}{}{\mathrm{ln}}{}\left({x}\right)}{{x}{-}{1}}$ (7.9.1.5)
 M > simplify(eta1, symbolic);
 ${\mathrm{ln}}{}\left({{y}}^{{4}}{+}{{x}}^{{4}}\right)$ (7.9.1.6)
 M > eta2 := DeRhamHomotopy(omega2, initialpoint = [x = 1, y = 0], path = "zigzag");
 ${\mathrm{η2}}{≔}{-}{\mathrm{arctan}}{}\left(\frac{{{y}}^{{2}}}{{{x}}^{{2}}}\right)$ (7.9.1.7)
 M > eta4 := DeRhamHomotopy(omega4, integrallimits = [infinity, 1]);
 ${\mathrm{η4}}{≔}\frac{{{y}}^{{2}}{}{{x}}^{{2}}}{{{x}}^{{2}}{+}{{y}}^{{2}}}$ (7.9.1.8)

It is a nice exercise to prove that the function eta2 is a smooth function, if we define its value to be Pi/2 at x = 0.

We check these results.

 M > ExteriorDerivative(eta1) &minus omega1;
 ${0}{}{\mathrm{dx}}$ (7.9.1.9)
 M > ExteriorDerivative(eta2) &minus omega2;
 ${0}{}{\mathrm{dx}}$ (7.9.1.10)
 M > ExteriorDerivative(eta4) &minus omega4;
 ${0}{}{\mathrm{dx}}$ (7.9.1.11)