このページでは Groebner パッケージの最も基本的な使い方、つまり Groebner 基底の計算や関連した (可換) 多項式環上の操作について説明しています。Groebner パッケージは実際には、非可換多項式環上の多項式 (Groebner details をご参照ください) や、(可換、または非可換) 多項式環上の可群 (Groebner Bases for Modules をご参照ください) における操作を行う事ができます。

Groebner パッケージの各コマンドは、コマンド名の 長い名前 短い名前 いづれの呼び出し名でも呼び出すことができます。

Groebner パッケージはモジュールとして実装されていますので、Groebner:-command の形式でも呼び出すことができます。詳細については Module Members をご参照ください。

利用可能なコマンドのリストを以下に示します。

Groebner パッケージの個々のコマンドのヘルプを参照するには Getting Help with a Command in a Package をご覧ください。

Groebner コマンドではよく使われる単項式順序を利用する事ができます。それらには全次数順序、辞書式順序、消去順序や行列を用いて定義する順序があります。詳細については monomial orders をご参照ください。

TestOrder コマンドは二つの単項式が、与えられた単項式順序でどちらが大きいかを返します。

LeadingCoefficient, LeadingMonomial, LeadingTerm はそれぞれ多項式の頭係数、頭単項式、頭項を計算します。

NormalForm コマンドは多項式の、与えられたイデアルにおける正規形を計算します。Reduce コマンドは多項式の、多項式リストによる簡約の結果を返します。InterReduce コマンドは多項式リストを互いに簡約します。NormalForm や Reduce コマンドは通常 (簡約) Groebner 基底を計算したあとに用いられます。

Basis コマンドは多項式イデアルの ( 簡約 ) Groebner 基底を計算します。RememberBasis コマンドは多項式系の Groebner 基底を計算することなく入力します。

Solve コマンドは生成元の集合を、連立代数方程式系として解くための前処理をします。

SPolynomial コマンドは二つの多項式の S-多項式を計算します。

UnivariatePolynomial コマンドは多項式イデアルの次数の最も低い一変数多項式を見つけます。

IsZeroDimensional コマンドはイデアルが高々有限個の解しか持っていないか (イデアルが 0 次元か) を、IsProper コマンドはイデアルが少なくとも一つの解を持っているかを判定します。

HilbertDimension, HilbertPolynomial, HilbertSeries コマンドはそれぞれイデアルの Hilbert 次元、 Hilbert 多項式、Hilbert 級数を計算します。

典型的なイデアルのメンバシップテストを以下に示します:

1. イデアルの Groebner 基底を求めるため、Groebner 基底計算を行います。(通常全次数順序 tdeg を用います);

2. Groebner[Reduce] を呼び出して結果が 0 かどうかを見ます。

Groebner 基底を用いた典型的な変数消去の手順を以下に示します:

1. 消去順序に関する Groebner 基底を計算します。(lexdeg を用います);

2. 消去される変数が現れていない多項式を選びます。

適切であれば、Groebner パッケージのほとんどのコマンドは I, radicals, RootOf などで表される代数的数や代数関数も入力することができます。MultiplicationMatrix, NormalSet, Solve は当てはまりません。また、PolynomialIdeal 形式のデータも、これらの入力として用いることができます。

Groebner パッケージは PolynomialIdeals パッケージと連携して使うことができます。

注意: HilbertDimension, IsProper, IsZeroDimensional, UnivariatePolynomial はいずれのパッケージでも同じ名前で定義されており、関数として同様に動作します。with コマンドを用いて両方のパッケージを読み込むと、これらの関数は後で読み込んだパッケージの関数に関連付けられます。しかしもう一方の関数へも、長い呼び出し名を用いる事でアクセスすることができます。

with(Groebner);

G:={x+y+z, x*y+y*z+z*x, x*y*z-1};

B:=Basis(G,tdeg(x,y,z));

NormalForm(x^3-1,B,tdeg(x,y,z));

NormalForm(x^2,B,tdeg(x,y,z));

param:={x=(1-t^2)/(1+t^2),y=2*t/(1+t^2)};

Basis(map(eq->numer(lhs(eq)-rhs(eq)),param),lexdeg([t],[x,y]));

remove(has,%,t);

phi:=x^3+2*x*y*z-z^2;

const:=x^2+y^2+z^2-1;

G:={seq(diff(phi,v)-diff(const,v)*t,v=[x,y,z]),const};

GB:=Basis(G,lexdeg([t],[x,y,z]));

remove(has,GB,t);

GB2:=Basis(%,lexdeg([x,y],[z]));

op(remove(has,GB2,{x,y}));

sol_z:=solve(%,z);

map(op,[seq(map(`union`,[solve(convert(subs(z=i,GB2),set),{x,y})],{z=i}),i=sol_z)]);

min(op(map(subs,%,phi))),max(op(map(subs,%,phi)));

G:=[3*y^2-8*z^3,x^2-2*z*x+5,3*y^3+8*x*y^2]:
HilbertDimension(G,tdeg(y,x,z));

HilbertSeries(G,tdeg(y,x,z),s);

eval(%,s=1);

HilbertPolynomial(G,tdeg(y,x,z),s);

G:=[x^3*y^2+3*x^2*y^2+y^3+1]:
HilbertDimension(G,tdeg(x,y));

HilbertSeries(G,tdeg(x,y),s);

series(%,s,10);

HilbertPolynomial(G,tdeg(y,x),s);

G:=[x^2+y^2-I,sqrt(2)*y+sqrt(2)*(x-sqrt(2))-1];

GB:=Basis(G,tdeg(x,y));

G:=[x^2-2*x*z+5,x*y^2+y*z^3,3*y^2-8*z^3]:
G mod 5;

Basis(G,plex(x,y,z),characteristic=5);

L:=1+x+y+z+x^2+y^2+z^2;

LeadingMonomial(L,plex(x,y,z));

LeadingMonomial(L,plex_min(x,y,z));

G:=[y*w^2-z^3,x*w^3-z^4];

Basis(G,plex(w,x,y,z));

Reduce(w^5*x^3*y^2*z,%,plex(w,x,y,z));

Basis(G,plex_min(w,x,y,z));

Reduce(w^5*x^3*y^2*z,%,plex_min(w,x,y,z));