Wait コマンドは状態変数識別子 condId が呼び出されるまで待機します。Wait コマンドは、ミューテックス識別子 mutexId を使うことができます。現在のスレッドは mutexId を Threads[Mutex][Lock] コマンドによって得る必要があります。

Wait を呼び出すと、スレッドは待機し mutexId は自動的にロック解除をします。再びスレッドを動かすと、スレッドは待機から返る前に、 mutexId を再び取得します。

他のスレッドは待機中から再スタートさせる引数 condId を持つ Signal or Broadcast コマンドを使うことができます。

Signal および Broadcast コマンドはロックされている mutexId を必要としませんが、よく使われます。Signal または Broadcast を呼ぶ間ロックしている mutexId によって、同時に Wait に入るスレッドがないように保証します。

状態変数の使い方の概要については Condition Variable を参照ください。

Producer := proc( m, cp, cc, max, mindiff )
    global tab, e;
    local i,j,n;
    Threads:-Mutex:-Lock( m );
    j := 0;
    tab[ "maxjob" ] := mindiff;
    tab[ "curjob" ] := 1;
    for j from 1 to mindiff
    do
        tab[ j ] := 2*j;
    end do;
    Threads:-ConditionVariable:-Signal( cp );
    Threads:-Mutex:-Unlock( m );
    n := false;
    while ( e )
    do
        Threads:-Mutex:-Lock( m );
        j := tab[ "maxjob" ];
        if ( j - tab[ "curjob" ] > mindiff/2 ) then
            n := true;
            Threads:-ConditionVariable:-Wait( cp, m );
        end if;
        for i from j to tab[ "curjob" ] + mindiff
        do
            tab[ i ] := 2*i;
        end do;
        tab[ "maxjob" ] := tab[ "curjob" ] + mindiff;
        if ( n ) then
            Threads:-ConditionVariable:-Broadcast( cc );
            n := false;
        end if;
        Threads:-Mutex:-Unlock( m );
    end do;
end proc:

Consumer := proc( m, cp, cc, max )
    global tab, e;
    local n, i, j, num;
    num := 0;
    while ( num < max )
    do
        Threads:-Mutex:-Lock( m );
        while ( tab[ "curjob" ] = tab[ "maxjob" ] )
        do
            Threads:-ConditionVariable:-Signal( cp );
            Threads:-ConditionVariable:-Wait( cc, m );
        end do;
        n := tab[ "curjob" ];
        j := tab[ n ];
        tab[ "curjob" ] := n + 1;
        Threads:-Mutex:-Unlock( m );
        j := add( i, i=1..j );
        num := num+1;
        Threads:-Mutex:-Lock( m );
        tab[ n ] := j;
        Threads:-Mutex:-Unlock( m );
    end do;
end proc:

tab := table( ):
m := Threads:-Mutex:-Create();

                                     m := 1

cc := Threads:-ConditionVariable:-Create();

                                    cc := 1

cp := Threads:-ConditionVariable:-Create();

                                    cp := 2

e := true:

Threads:-Mutex:-Lock( m );
id1 := Threads:-Create( Producer( m, cp, cc, 31, 10 ) );

                                    id1 := 1

Threads:-ConditionVariable:-Wait( cp, m );
Threads:-Mutex:-Unlock( m );

id2 := [ seq( Threads:-Create( Consumer( m, cp, cc, 100 ) ), i=1..5 ) ];

                             id2 := [2, 3, 4, 5, 6]

Threads:-Wait( op( id2 ) );
Threads:-Mutex:-Lock( m );

e := false:
Threads:-ConditionVariable:-Signal( cp );
Threads:-Mutex:-Unlock( m );
Threads:-Wait( id1 );

print( tab[ "curjob" ] );

                                      501

print( tab[233] );

                                     108811

print( add( i, i=1..2*233 ) );

                                     108811