通常は、RootOf は複数の値を表しています。したがって、 RootOfs を含む式は複数の値または式に評価されます。手続き allvalues は、 RootOfs の異なる値の組合せにより生成されるすべての値 (または式) を式列の形で返します。

手続き allvalues は、solve を用いてこれらの根の記号表現を求めようとします。もし solve の呼び出しにより根の一部しか得られず _SolutionsMayBeLost を true (真) に設定しておくと、allvalues は大域的変数 _ValuesMayBeLost を true に設定して、この一部の根を用いて作業を続けます。

- 多項式の根に関しては、オプション 'implicit' の指定がない場合、 allvalues はベキ根による表現を返そうとします (以下を参照)。そのような式が得られなかった場合、indexed RootOf が用いられます。

- 多項式以外の式の根に関しては、記号表現が得られる場合もあれば、得られない場合もあります。

記号による解が得られた場合、いくつかの解が抜けているかもしれないことに注意して下さい。ある場合には、解の集合が以下のような接頭辞を用いてパラメータ表示されます。Z は整数値、 _NN は非負の整数値、_B はブール値 (0 または 1) です。 solve も参照して下さい。

solve が根の記号表現を求められないときは、数値による近似値を探すために fsolve が用いられます。数値による近似解が得られると、数値セレクタを持つ RootOfs が返されます。もし fsolve によりすべての解が得られたかどうか判定できない場合、大域変数 _ValuesMayBeLost が true に設定されます。

記号表現も数値による近似もどちらも得られない場合、 RootOf は展開されません。しかしながら、RootOf に対応する方程式の複素数解が存在しないことを Maple が示せる場合、 NULL が返されてきます。

以下のオプションを用いることができます。

- 名前 'independent' (独立) または 'dependent' (従属)。オプション 'dependent' が指定された場合、特定の RootOf(p) は expr に現れるところのそれぞれで同じ根を表します。 これはデフォルトです。これに対して、オプションが 'independent' の場合、 RootOf(p) はそれぞれ独立したものとして扱われます。このオプションは、一価であることを示すセレクタを持つ RootOf に対して影響を与えることはありません。

- 名前 'explicit' (陽) または 'implicit' (陰)。オプション 'explicit' が与えられると、allvalues は多項式の根に対して根号を用いた式を求めようとします。これがデフォルトです。オプション 'implicit' が指定された場合、インデックス付けされた RootOf が用いられます。

- 1つの RootOf または RootOf の集合。指定された RootOf は allvalues により展開されず、不活性なままです。

関数 allvalues は RootOf のセレクタに影響されます。

- セレクタが数値近似の場合、RootOf は一価のオブジェクト、すなわちセレクタに最も近い根として扱われます。

- セレクタが範囲の場合、根をこの範囲内で探します。

- セレクタが index=expr1 の形のインデックスの場合、expr1 が集合または範囲である場合を除いて、RootOf は一価のオブジェクトとみなされます。

- セレクタが label=expr2 の形のインデックスの場合、RootOf は多価のオブジェクトとみなされます。

入れ子になった RootOf は allvalues でサポートされています。

e1 := RootOf(_Z^2-1) + 1/RootOf(_Z^4-1)^2;

allvalues(e1);

e2 := RootOf(_Z^3-1);

allvalues(e2);

allvalues(e2,'implicit');

f1 := RootOf((x-1)*(cos(x)-x));

allvalues(f1);

f2 := RootOf((x+1)*(cos(x)-x),1);

allvalues(f2);

allvalues(sin(RootOf(_Z^2-a^2))*RootOf(_Z^2-1));

e3 := RootOf(_Z^2-1+RootOf(_Z^2-2));

allvalues(e3,RootOf(_Z^2-2));

allvalues(e3,RootOf(_Z^2-2),implicit);

allvalues(e3,e3);

allvalues(e3,{e3,RootOf(_Z^2-2)});

e4 := RootOf(_Z^2-1) - 1/RootOf(_Z^2-1);

allvalues(e4);

allvalues(e4, 'independent');

e5 := {allvalues(RootOf(_Z^5-_Z+1))};

evalf(e5);

e6 := RootOf(x^2-2)+RootOf(x^2-2,index=1);

allvalues(e6);

allvalues(e6,implicit);

e7 := RootOf(_Z^2-2,label=1)+RootOf(_Z^2-2,label=2);

allvalues(e7);

e8 := RootOf(sin(_Z));

allvalues(e8);

e9 := RootOf(exp(_Z));

allvalues(e9);
e10 := solve(8*z^8-100*z^6+438*z^4-760*z^2+361);

map(evalf@allvalues,[e10]);