plot3d コマンドは、3 次元の曲面のプロットを計算します。最初の 2 つの呼び出し手順は、直行座標系における曲面プロットを記述します。一方、次の 2 つは、パラメータ表示による曲面プロットを記述します。曲線や他のオブジェクトをプロットする能力は、plots パッケージにあります。

最初の呼び出し手順 plot3d(expr,x=a..b,y=c..d) において、式 expr は、名前 x と y の Maple 式でなくてはなりません。範囲 a..b は、実定数に評価されなくてはいけません。範囲 c..d は、実定数または x の式に評価されなくてはいけません。これらは、expr がプロットされる範囲を指定します。

2 番目の呼び出し plot3d(f,a..b,c..d) では、f は手続きまたは 2 個の引数を取る演算子でなくてはいけません。演算子記法が用いられなければいけません。すなわち、手続き名は、指定されたパラメータなしで与えられ、そして、範囲は等式としてではなく単に a..b の形で与えられなくてはいけません。2 番目の範囲 c..d は、実定数または 1 変数の手続きに評価される引数を持ち得ます。

パラメータ表示の曲面は、2 変数に関する 3 つの式 exprf, exprg, exprh によって、定義することができます。3 番目の呼び出し plot3d([ exprf,exprg,exprh ],s=a..b,t=c..d) において、exprf, exprg, exprh は名前 s と t の Maple 式でなくてはいけません。4番目の呼び出し plot3d([ f,g,h ],a..b,c..d) において、f, g，h は Maple 手続きまたは 2 個の引数を取る演算子でなくてはいけません。他の呼び出し方についても、演算子表記が用いられなければいけません。

任意の追加される引数はオプションとして解釈され、option = value の形の等式で指定されます。たとえば、オプション grid = [m,n] は、 m と n は正の整数であり、プロットがそれぞれ a..b と c..d の範囲でじ間隔の m × n 格子上に作成されることを指定します。デフォルトでは 25 × 25 のグリッドが用いられます。よって、625 個の点が生成されます。他のオプションには、別の座標系の記述や表示スタイルなどが含まれます。ヘルプページ plot3d[options] を参照して下さい。

呼び出し手順の第1引数が、曲面の集合、または、リストである場合、曲面が同時にプロットされます。リストが与えられた場合、曲面のリストの要素に対応する要素をもつ、特定のオプションの値もリストで与えることになります。 リストを値としてとることができるオプションは、つぎのものです。: color, coords, grid, linestyle, numpoints, shading, style, symbol, symbolsize, thickness, transparency. 3 つの式 または手続きのリストは、常にパラメータによるプロットと解釈されます。 3 つの異なるプロットのリストを指定するためには、オプション plotlist=true (または、単に plotlist) を与える必要があります。

plot3d が引数を評価するとき、評価中に生じるすべてのエラーは plot パッケージにより削除されます。 式の評価中に何か悪いことが起きた場合は、空のプロットという結果になります。

plot3d の呼び出しの結果は、プロット描くのに十分な情報を含む PLOT3D データ構造になります。ユーザは、PLOT3D 値を変数に割り当て、ファイルとして保存し、そして、再表示のために読み込むことができます。ヘルプページ plot3d[structure] を参照して下さい。

すべてのプロットされる式は、数値的に、すなわち、記号的ではなく浮動小数点の式として評価されます。

他の種類の 3 次元プロットに対しては、plots を参照してください。

plot3d(sin(x+y),x=-1..1,y=-1..1);
plot3d(binomial,0..5,0..5,grid=[10,10]);

plot3d((1.3)^x * sin(y),x=-1..2*Pi,y=0..Pi,coords=spherical,style=patch);
plot3d([1,x,y],x=0..2*Pi,y=0..2*Pi,coords=toroidal(10),scaling=constrained);
plot3d(sin(x*y),x=-Pi..Pi,y=-Pi..Pi,style=contour);

plot3d(sin(x*y),x=-Pi..Pi,y=-x..x);
p:= proc(x,y) if x^2 < y then cos(x*y) else x*sin(x*y) end if end proc:
h:= proc(x) x^2  end proc:
plot3d(p,-2..2,-1..h);
plot3d([x*sin(x)*cos(y),x*cos(x)*cos(y),x*sin(y)],x=0..2*Pi,y=0..Pi);
plot3d(x*exp(-x^2-y^2),x=-2..2,y=-2..2,grid=[49,49]);
plot3d(x*exp(-x^2-y^2),x=-2..2,y=-2..2,color=x);
plot3d(p,-2..2,-1..h,color=h);

plot3d({sin(x*y), x + 2*y}, x=-Pi..Pi, y=-Pi..Pi);
plot3d([sin(x*y), x + 2*y], x=-Pi..Pi, y=-Pi..Pi, color=[blue,green]);
c1:= [cos(x)-2*cos(0.4*y), sin(x)-2*sin(0.4*y), y]:
c2:= [cos(x)+2*cos(0.4*y), sin(x)+2*sin(0.4*y), y]:
c3:= [cos(x)+2*sin(0.4*y), sin(x)-2*cos(0.4*y), y]:
c4:= [cos(x)-2*sin(0.4*y), sin(x)+2*cos(0.4*y), y]:
plot3d({c1, c2, c3, c4}, x=0..2*Pi, y=0..10, grid=[25,15], style=patch, color=sin(x));
plot3d([c1, c2, c3],x=0..2*Pi, y=0..10, grid=[25,15], style=patch, color=[blue,green,yellow], plotlist);