Most Maple procedures have what are known as "standard evaluation rules." These rules govern the way in which arguments passed to a procedure are evaluated before being bound to the formal parameters of the procedure.

Standard evaluation rules mean that arguments are evaluated in an unspecified order, in the scope of the caller, before parameter binding occurs. Both last name evaluation and one level evaluation of locals apply to the evaluation of the argument expressions. Thus, procedures called at the top level are passed their arguments after they have been fully evaluated, while those called within other procedures are passed their arguments after they have been evaluated one level.

Some Maple procedures have so-called "special evaluation rules." This means that the arguments are not evaluated according to the standard evaluation rules. Instead, some arguments may not be (fully) evaluated, a specific evaluation order may be prescribed, or a non-standard evaluator may be used to evaluate one or more arguments.

Most procedures that have special evaluation rules are builtin. It is possible, however, for a user to write a procedure with special evaluation rules by using an argument declared to be of one of the types uneval and evaln. This can only be done for a fixed number of named arguments. (There is no way to write a procedure that takes an arbitrary number of unevaluated arguments.) It is not possible to alter the order in which the arguments to a procedure are evaluated. (Often, however, this effect can be achieved by suppressing the evaluation of the arguments, and then evaluating the parameters explicitly within the body of the procedure in the desired order.)

The following builtin user procedures have special evaluation rules.

Writing procedures with special evaluation rules is generally to be avoided unless absolutely necessary for correct operation.

p := proc( x ) print( x ); end proc;

proc()
    local a, b;
    a := b;
    b := 2;
    p(a);
end proc();

p := proc( x::uneval ) print( x ); end proc;

proc()
    local a, b;
    a := b;
    b := 2;
    p(a);
end proc();

evalf( proc() print( FIRST ); Pi end(), proc() print( SECOND ); 15 end() );

p := proc( a::uneval, b::uneval )
    local    ea, eb;
    eb := eval( b ); # evaluate second
    ea := eval( a ); # evaluate first
    [ ea, eb ]
end proc:

p( proc() print(FIRST); 2 end(), proc() print(SECOND); 3 end() );