関数 RootOf は 1 変数の方程式のすべての根を表すプレースホルダです。特に、これは Maple の代数的数、代数関数 (evala を参照)、そして有限体  GF(p^k), p は素, k > 1 (mod を参照) に対する標準的表現です。

Maple は多項式の方程式や方程式系の解 (solve を参照)、固有値、有理関数の積分 (int を参照) を表すために自動的に RootOf を生成します。 Maple は RootOf 式に対して diff, series, evalf, and simplify を適用する方法を知っています。

x が指定されていないと、expr は 1 変数の式かまたは _Z の式でなければいけません。 この場合、RootOf はそれぞれその 1 変数または _Z に関する expr の根を表します。第1引数が方程式でなければ、方程式 expr = 0 であると仮定します。

RootOf 関数はその引数の有効性をチェックして、1 次多項式に対してそれを解きます。RootOf は、引数を primitive (原始的) にして、RootOf を大域変数  _Z を用いて表すことにより 1 引数の標準形で表されます。

alias 関数は、よりコンパクトな表記を得るためにしばしば RootOf と共に用いられます。Maple は入れ子の RootOf を使うことができますが、alias は別の  alias を用いて定義することはできないことに注意して下さい。alias はインタラクティブなツールで、Maple の手続きの中で用いるべきではないことにも注意して下さい。

expr が体 F 上の既約多項式ならば、alpha = RootOf(expr) は F 上の次数 degree(expr, x) の代数拡大体 K を表します。ここで K の要素は alpha の多項式として表されます。

evala のコンテクストにおける評価では代数的数や代数関数を表すために RootOf 表記が用いられます。

mod 演算子のコンテクストにおける評価では有限体を表すために RootOf 表記が用いられます。有限体 GF(p^k) の要素は、 expr を k mod p 次の既約多項式として、RootOf(expr) の多項式として表されます (すなわち、mod p の整数上の代数拡大)。

RootOf は代数拡大に限定されません。たとえば、RootOf(cos(x)=x, x) のような超越方程式の解を表すのに用いることができます。

(オプションの) 第 3 引数は根のセレクタです。セレクタは特定の根または根の部分集合を指定することを意味します。同じ多項式の (必ずしも指定されない) いくつかの根を扱うのに用いることもできます。RootOf 関数は次のセレクタをサポートしています。

- 数値近似 c,

- 2 つの複素数 a と b で定義されるバウンディング・ボックス。数はボックスの左下と右上の隅の順で与えなければいけません (あるいは実数の区間の場合は、左と右の端点)。

- 構文規則 index=i で用いる添え字 i。i が整数ならば、RootOf はヘルプページ RootOf,indexed で解説されている順序における方程式の i 番目の根を表します。このオプションは方程式の根が可付番のときに限り使うべきです。RootOf,indexed を見て下さい。

- ラベル e は構文規則 label=e を用います。本質的に、ラベルは同じ方程式のいくつかの指定されていない根を区別することを意図しています。数値的に評価したときには、ラベル付けられた RootOf は主枝の値を返します。すなわち、evalf(RootOf(expr,label=...)) は evalf(RootOf(expr,index=1)) に等価です。

RootOf(x^2+1=0);

RootOf(x^2-a*x=b, x);

RootOf(a*b^2+a/b, b);

RootOf(a*x+b, x);

RootOf(x^3-1, x) mod 7;

RootOf(x^2-2*x+1, x) mod 5;

alias(alpha = RootOf(x^2+x+1)):
Normal(1/alpha) mod 2;

RootOf(x^2=2, x, -1.41);

evalf(%);

RootOf( x^3-2, x, -0.7-1.1*I .. -0.6-1.0*I );

evalf(%);

r1 := RootOf(_Z^4+_Z^2+1, index=1);

evalf(r1);

allvalues(r1);

r2 := RootOf(_Z^4+_Z^2+1, label=1);

evalf(r2);

allvalues(r2);

alias(beta = RootOf(y^3-x^2+1, y)):
diff(beta+beta^2/(x-1), x);

int(%, x);

RootOf(y*exp(y)-x, y);

series(%, x);

asympt(%%, x);

RootOf(cos(x)-a, x);

series(%, a);

alpha:=RootOf(x^3-a*x-1, x);

beta:=RootOf(x^2-alpha, x);

evala(beta^7);